[arch-commits] Commit in python-braintree/repos (community-any community-any/PKGBUILD)

[Felix Yan]

    Date: Wednesday, April 22, 2015 @ 07:40:36
  Author: fyan
Revision: 131874

archrelease: copy trunk to community-any

Added:
  python-braintree/repos/community-any/
  python-braintree/repos/community-any/PKGBUILD
    (from rev 131873, python-braintree/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-braintree/repos/community-any/PKGBUILD (from rev 131873, python-braintree/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-04-22 05:40:36 UTC (rev 131874)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-braintree
+pkgname=(python-braintree python2-braintree)
+_pkgname=braintree
+pkgver=3.13.0
+pkgrel=1
+pkgdesc="Braintree Python Library"
+arch=('any')
+url="https://www.braintreepayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests')
+checkdepends=('python-nose' 'python2-nose')
+source=("$pkgbase-$pkgver::https://github.com/braintree/braintree_python/archive/${pkgver}.tar.gz")
+sha512sums=('4c84dc75cb93747c59f5ce548b4eed9f7311ff1ffa3f3acbfa87c1dac2afeab1d42b17f2419956fdf30d6c26d264fd22525b860daa26e3af2752970c02aaac2b')
+
+prepare() {
+  cp -a ${_pkgname}_python-$pkgver{,-py2}
+}
+
+build() {
+  cd ${_pkgname}_python-$pkgver
+  python setup.py build
+
+  cd ../${_pkgname}_python-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd ${_pkgname}_python-$pkgver
+  nosetests3 tests/unit
+
+  cd ../${_pkgname}_python-$pkgver-py2
+  nosetests2 tests/unit
+}
+
+package_python-braintree() {
+  depends=('python-requests')
+
+  cd ${_pkgname}_python-$pkgver
+  python setup.py install -O1 --root "${pkgdir}"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-braintree() {
+  depends=('python2-requests')
+
+  cd ${_pkgname}_python-$pkgver-py2
+  python2 setup.py install -O1 --root "${pkgdir}"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+