[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, April 23, 2015 @ 04:54:59
  Author: fyan
Revision: 132020

addpkg: python-colorama 0.3.3-2

Added:
  python-colorama/
  python-colorama/repos/
  python-colorama/trunk/
  python-colorama/trunk/PKGBUILD

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Added: python-colorama/trunk/PKGBUILD
===================================================================
--- python-colorama/trunk/PKGBUILD	                        (rev 0)
+++ python-colorama/trunk/PKGBUILD	2015-04-23 02:54:59 UTC (rev 132020)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Alexander Duscheleit <jinks at archlinux.us>
+
+pkgbase=python-colorama
+pkgname=('python-colorama' 'python2-colorama')
+pkgver=0.3.3
+pkgrel=2
+pkgdesc="Python API for cross-platform colored terminal text."
+arch=('any')
+url="http://pypi.python.org/pypi/colorama"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock')
+source=("git+https://github.com/tartley/colorama.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a colorama{,-py2}
+}
+
+build() {
+  cd "$srcdir/colorama"
+  python setup.py build
+
+  cd "$srcdir/colorama-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/colorama"
+  py.test
+
+  cd "$srcdir/colorama-py2"
+  py.test2
+}
+
+package_python-colorama() {
+  depends=('python')
+
+  cd "$srcdir/colorama"
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-colorama() {
+  depends=('python2')
+
+  cd "$srcdir/colorama-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-colorama/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property