[arch-commits] Commit in python-colorama/repos (community-any community-any/PKGBUILD)

Felix Yan fyan at archlinux.org
Thu Apr 23 02:59:29 UTC 2015


    Date: Thursday, April 23, 2015 @ 04:59:29
  Author: fyan
Revision: 132021

archrelease: copy trunk to community-any

Added:
  python-colorama/repos/community-any/
  python-colorama/repos/community-any/PKGBUILD
    (from rev 132020, python-colorama/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: python-colorama/repos/community-any/PKGBUILD (from rev 132020, python-colorama/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-04-23 02:59:29 UTC (rev 132021)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Alexander Duscheleit <jinks at archlinux.us>
+
+pkgbase=python-colorama
+pkgname=('python-colorama' 'python2-colorama')
+pkgver=0.3.3
+pkgrel=2
+pkgdesc="Python API for cross-platform colored terminal text."
+arch=('any')
+url="http://pypi.python.org/pypi/colorama"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest' 'python2-pytest' 'python-mock' 'python2-mock')
+source=("git+https://github.com/tartley/colorama.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a colorama{,-py2}
+}
+
+build() {
+  cd "$srcdir/colorama"
+  python setup.py build
+
+  cd "$srcdir/colorama-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/colorama"
+  py.test
+
+  cd "$srcdir/colorama-py2"
+  py.test2
+}
+
+package_python-colorama() {
+  depends=('python')
+
+  cd "$srcdir/colorama"
+  python setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-colorama() {
+  depends=('python2')
+
+  cd "$srcdir/colorama-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+# vim:set ts=2 sw=2 et:



More information about the arch-commits mailing list