[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Sat Aug 8 03:23:55 UTC 2015


    Date: Saturday, August 8, 2015 @ 05:23:54
  Author: fyan
Revision: 138093

addpkg: python-setuptools_scm 1.5.5-2

Added:
  python-setuptools_scm/
  python-setuptools_scm/repos/
  python-setuptools_scm/trunk/
  python-setuptools_scm/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-setuptools_scm/trunk/PKGBUILD
===================================================================
--- python-setuptools_scm/trunk/PKGBUILD	                        (rev 0)
+++ python-setuptools_scm/trunk/PKGBUILD	2015-08-08 03:23:54 UTC (rev 138093)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Hugo Osvaldo Barrera <hugo at barrera.io>
+
+pkgbase=python-setuptools_scm
+pkgname=(python-setuptools_scm python2-setuptools_scm)
+_pkgname=setuptools_scm
+pkgver=1.5.5
+pkgrel=2
+pkgdesc="Handles managing your python package versions in scm metadata."
+arch=('any')
+url="https://github.com/pypa/setuptools_scm"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/pypa/setuptools_scm.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a $_pkgname{,-py2}
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py build
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py build
+}
+
+package_python-setuptools_scm() {
+  depends=('python-setuptools')
+
+  cd "${srcdir}/${_pkgname}"
+  python setup.py egg_info
+  python setup.py install --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-setuptools_scm() {
+  depends=('python2-setuptools')
+
+  cd "${srcdir}/${_pkgname}-py2"
+  python2 setup.py egg_info
+  python2 setup.py install --root "$pkgdir"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-setuptools_scm/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list