[arch-commits] Commit in python-flexmock/repos (community-any community-any/PKGBUILD)
Felix Yan
fyan at archlinux.org
Fri Dec 4 03:32:09 UTC 2015
Date: Friday, December 4, 2015 @ 04:32:08
Author: fyan
Revision: 148263
archrelease: copy trunk to community-any
Added:
python-flexmock/repos/community-any/
python-flexmock/repos/community-any/PKGBUILD
(from rev 148262, python-flexmock/trunk/PKGBUILD)
----------+
PKGBUILD | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 51 insertions(+)
Copied: python-flexmock/repos/community-any/PKGBUILD (from rev 148262, python-flexmock/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2015-12-04 03:32:08 UTC (rev 148263)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-flexmock
+pkgname=('python-flexmock' 'python2-flexmock')
+pkgver=0.9.7
+pkgrel=1
+pkgdesc="Mock/Stub/Spy library for Python"
+arch=('any')
+license=('BSD')
+url="http://has207.github.com/flexmock"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/has207/flexmock.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a flexmock{,-py2}
+}
+
+build() {
+ cd "$srcdir/flexmock"
+ python setup.py build
+
+ cd "$srcdir/flexmock-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/flexmock"
+ nosetests3
+
+ cd "$srcdir/flexmock-py2"
+ nosetests2
+}
+
+package_python-flexmock() {
+ depends=('python')
+
+ cd flexmock
+ python setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-flexmock() {
+ depends=('python2')
+
+ cd flexmock-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+ install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
More information about the arch-commits
mailing list