[arch-commits] Commit in lib32-libproxy/repos (2 files)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Sun Dec 6 19:16:35 UTC 2015
Date: Sunday, December 6, 2015 @ 20:16:35
Author: bpiotrowski
Revision: 149081
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-libproxy/repos/multilib-staging-x86_64/
lib32-libproxy/repos/multilib-staging-x86_64/PKGBUILD
(from rev 149080, lib32-libproxy/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: lib32-libproxy/repos/multilib-staging-x86_64/PKGBUILD (from rev 149080, lib32-libproxy/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2015-12-06 19:16:35 UTC (rev 149081)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: TryA <tryagainprod at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: josephgbr <rafael.f.f1 at gmail.com>
+
+pkgname=lib32-libproxy
+pkgver=0.4.11
+pkgrel=2
+pkgdesc='A library that provides automatic proxy configuration management'
+arch=('x86_64')
+url='http://libproxy.googlecode.com'
+license=('LGPL')
+depends=('lib32-gcc-libs' 'libproxy')
+makedepends=('cmake' 'gcc-multilib' 'lib32-zlib')
+source=("http://libproxy.googlecode.com/files/libproxy-${pkgver}.tar.gz")
+md5sums=('3cd1ae2a4abecf44b3f24d6639d2cd84')
+
+build() {
+ cd libproxy-${pkgver}
+
+ export CC='gcc -m32'
+ export CXX='g++ -m32'
+ export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+ if [[ -d build ]]; then
+ rm -rf build
+ fi
+ mkdir build && cd build
+
+ cmake .. \
+ -DCMAKE_INSTALL_PREFIX='/usr' \
+ -DCMAKE_C_FLAGS="${CFLAGS}" \
+ -DCMAKE_CXX_FLAGS="$CXXFLAGS" \
+ -DCMAKE_SKIP_RPATH='TRUE' \
+ -DLIBEXEC_INSTALL_DIR='/usr/lib32/libproxy' \
+ -DLIB_SUFFIX='32' \
+ -DPERL_VENDORINSTALL='FALSE' \
+ -DWITH_{GNOME3,MOZJS,NATUS,NM,KDE4,PERL,PYTHON,WEBKIT}='FALSE'
+ make
+}
+
+package() {
+ cd libproxy-${pkgver}/build
+
+ make DESTDIR="${pkgdir}" install
+ rm -rf "${pkgdir}"/usr/{bin,include,share}
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list