[arch-commits] Commit in python-autobahn/repos (2 files)

[Anatol Pomozov]

    Date: Friday, December 11, 2015 @ 17:24:24
  Author: anatolik
Revision: 153040

archrelease: copy trunk to community-testing-any

Added:
  python-autobahn/repos/community-testing-any/
  python-autobahn/repos/community-testing-any/PKGBUILD
    (from rev 153039, python-autobahn/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-autobahn/repos/community-testing-any/PKGBUILD (from rev 153039, python-autobahn/trunk/PKGBUILD)
===================================================================
--- community-testing-any/PKGBUILD	                        (rev 0)
+++ community-testing-any/PKGBUILD	2015-12-11 16:24:24 UTC (rev 153040)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+
+pkgbase=python-autobahn
+pkgname=(python-autobahn python2-autobahn)
+pkgver=0.11.0
+pkgrel=1
+pkgdesc='Real-time framework for Web, Mobile & Internet of Things'
+arch=(any)
+url='http://autobahn.ws/python/'
+license=(MIT)
+makedepends=(python-setuptools python2-setuptools python-twisted python-six python-txaio python2-twisted python2-six python2-txaio)
+source=(https://pypi.python.org/packages/source/a/autobahn/autobahn-$pkgver.tar.gz)
+sha1sums=('6753ceb8dfe2ea9ad5b31426dee8ff172cf15891')
+
+prepare() {
+  cp -a autobahn-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/autobahn-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/autobahn-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/autobahn-$pkgver"
+  #It requires python-unittest2 in [community]
+  #python setup.py test
+
+  cd "$srcdir/autobahn-$pkgver-py2"
+  #python2 setup.py test
+}
+
+package_python-autobahn() {
+  depends=(python python-twisted python-six python-txaio)
+
+  cd "$srcdir/autobahn-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-autobahn() {
+  depends=(python2 python2-twisted python2-six python2-txaio)
+
+  cd "$srcdir/autobahn-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}