[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Monday, December 14, 2015 @ 17:56:35
  Author: anthraxx
Revision: 153308

addpkg: python-engineio 0.8.3-1

Added:
  python-engineio/
  python-engineio/repos/
  python-engineio/trunk/
  python-engineio/trunk/PKGBUILD

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Added: python-engineio/trunk/PKGBUILD
===================================================================
--- python-engineio/trunk/PKGBUILD	                        (rev 0)
+++ python-engineio/trunk/PKGBUILD	2015-12-14 16:56:35 UTC (rev 153308)
@@ -0,0 +1,66 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-engineio
+pkgname=('python-engineio' 'python2-engineio')
+pkgver=0.8.3
+pkgrel=1
+pkgdesc='Python implementation of the Engine.IO realtime server'
+url='https://github.com/miguelgrinberg/python-engineio'
+arch=('any')
+license=('MIT')
+makedepends=(
+  'python-setuptools' 'python-sphinx' 'python-six' 'python-pytest'
+  'python2-setuptools' 'python2-sphinx' 'python2-six' 'python2-pytest'
+)
+checkdepends=('python-mock' 'python-eventlet' 'python2-mock' 'python2-eventlet')
+options=('!makeflags')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/miguelgrinberg/python-engineio/archive/v${pkgver}.tar.gz)
+sha512sums=('d9d136d9cad76c7c31b72482b772f501c7d06c6e7099634f3e1ae31e22a9523e9e77e1e5407f759e720934aeb52edd3b8579f7ae3b3695da81903f1f4462285b')
+
+prepare() {
+  cp -ra ${pkgbase}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${pkgbase}-${pkgver}
+    python setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build
+  )
+  (cd ${pkgbase}-${pkgver}-py2
+    python2 setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build2
+  )
+}
+
+check() {
+  (cd ${pkgbase}-${pkgver}
+    py.test
+  )
+  (cd ${pkgbase}-${pkgver}-py2
+    py.test2
+  )
+}
+
+package_python-engineio() {
+  depends=('python-six')
+
+  cd ${pkgbase}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/engineio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+package_python2-engineio() {
+  depends=('python2-six')
+
+  cd ${pkgbase}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/engineio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: