[arch-commits] Commit in python-socketio/repos (community-any community-any/PKGBUILD)

[Levente Polyak]

    Date: Monday, December 14, 2015 @ 18:43:38
  Author: anthraxx
Revision: 153313

archrelease: copy trunk to community-any

Added:
  python-socketio/repos/community-any/
  python-socketio/repos/community-any/PKGBUILD
    (from rev 153312, python-socketio/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: python-socketio/repos/community-any/PKGBUILD (from rev 153312, python-socketio/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-12-14 17:43:38 UTC (rev 153313)
@@ -0,0 +1,64 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgbase=python-socketio
+pkgname=('python-socketio' 'python2-socketio')
+pkgver=0.8.1
+pkgrel=1
+pkgdesc='Python implementation of the Socket.IO realtime server'
+url='https://github.com/miguelgrinberg/python-socketio'
+arch=('any')
+license=('MIT')
+makedepends=('python-setuptools' 'python-sphinx' 'python-six' 'python-engineio'
+             'python2-setuptools' 'python2-sphinx' 'python2-six' 'python2-engineio')
+checkdepends=('python-pytest' 'python-mock' 'python2-pytest' 'python2-mock')
+options=('!makeflags')
+source=(${pkgbase}-${pkgver}.tar.gz::https://github.com/miguelgrinberg/python-socketio/archive/v${pkgver}.tar.gz)
+sha512sums=('94003bd0964f2191a60f10dc7e6615336fea14613dfec602fa148b9b0dbe82662fddda2128b57509bc9928489967990dddf8226769f479dcf5b37b1b145b3c7a')
+
+prepare() {
+  cp -ra ${pkgbase}-${pkgver}{,-py2}
+}
+
+build() {
+  (cd ${pkgbase}-${pkgver}
+    python setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build
+  )
+  (cd ${pkgbase}-${pkgver}-py2
+    python2 setup.py build
+    make -C docs man text SPHINXBUILD=sphinx-build2
+  )
+}
+
+check() {
+  (cd ${pkgbase}-${pkgver}
+    py.test
+  )
+  (cd ${pkgbase}-${pkgver}-py2
+    py.test2
+  )
+}
+
+package_python-socketio() {
+  depends=('python-six' 'python-engineio')
+
+  cd ${pkgbase}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+package_python2-socketio() {
+  depends=('python2-six' 'python2-engineio')
+
+  cd ${pkgbase}-${pkgver}-py2
+  python2 setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+  install -Dm 644 docs/_build/text/index.txt "${pkgdir}/usr/share/doc/${pkgname}/DOCUMENTATION"
+  install -Dm 644 docs/_build/man/socketio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: