[arch-commits] Commit in (5 files)

[Anatol Pomozov]

    Date: Tuesday, December 29, 2015 @ 00:16:03
  Author: anatolik
Revision: 154755

Create split package (py2/py3) for python lockfile library

Update package with correct homepage

Added:
  python-lockfile/
  python-lockfile/repos/
  python-lockfile/trunk/
  python-lockfile/trunk/PKGBUILD
Deleted:
  python2-lockfile/

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-lockfile/trunk/PKGBUILD
===================================================================
--- python-lockfile/trunk/PKGBUILD	                        (rev 0)
+++ python-lockfile/trunk/PKGBUILD	2015-12-28 23:16:03 UTC (rev 154755)
@@ -0,0 +1,50 @@
+# $Id$
+
+pkgbase=python-lockfile
+pkgname=(python-lockfile python2-lockfile)
+pkgver=0.12.2
+pkgrel=1
+pkgdesc='Platform-independent file locking module'
+arch=(any)
+url='https://github.com/openstack/pylockfile'
+license=(MIT)
+makedepends=(python-setuptools python2-setuptools)
+checkdepends=(python-jinja python2-jinja python-nose python2-nose python-docutils python2-docutils) # tests need older version of python-sphinx
+source=(https://pypi.python.org/packages/source/l/lockfile/lockfile-$pkgver.tar.gz)
+sha1sums=('c2ac46e48585e5f8f8d57ccc55ca83faa8b53b86')
+
+prepare() {
+  cp -a lockfile-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/lockfile-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/lockfile-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/lockfile-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/lockfile-$pkgver-py2"
+  python2 setup.py test
+}
+
+package_python-lockfile() {
+  depends=(python)
+
+  cd "$srcdir/lockfile-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-lockfile() {
+  depends=(python2)
+
+  cd "$srcdir/lockfile-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}


Property changes on: python-lockfile/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property