[arch-commits] Commit in (4 files)

[Anatol Pomozov]

    Date: Tuesday, December 29, 2015 @ 01:42:38
  Author: anatolik
Revision: 154770

Move package from AUR

Added:
  python-daemon/
  python-daemon/repos/
  python-daemon/trunk/
  python-daemon/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: python-daemon/trunk/PKGBUILD
===================================================================
--- python-daemon/trunk/PKGBUILD	                        (rev 0)
+++ python-daemon/trunk/PKGBUILD	2015-12-29 00:42:38 UTC (rev 154770)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-daemon
+pkgname=(python-daemon python2-daemon)
+pkgver=2.1.0
+pkgrel=2
+pkgdesc='Library to implement a well-behaved Unix daemon process'
+arch=(any)
+url='https://pypi.python.org/pypi/python-daemon'
+license=(Apache)
+makedepends=(python-setuptools python2-setuptools python-docutils python2-docutils python-lockfile python2-lockfile)
+checkdepends=(python-mock python2-mock python-testscenarios python2-testscenarios)
+source=(https://pypi.python.org/packages/source/p/python-daemon/python-daemon-$pkgver.tar.gz)
+sha1sums=('4a4e406a40bc69601d0da9c7804a4e3349d7805d')
+
+prepare() {
+  cp -a python-daemon-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/python-daemon-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/python-daemon-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/python-daemon-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/python-daemon-$pkgver-py2"
+  python2 setup.py test
+}
+
+package_python-daemon() {
+  depends=(python python-lockfile)
+
+  cd "$srcdir/python-daemon-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.ASF-2 "$pkgdir/usr/share/licenses/$pkgname/LICENSE.ASF-2"
+  install -Dm644 LICENSE.GPL-3 "$pkgdir/usr/share/licenses/$pkgname/LICENSE.GPL-3"
+}
+
+package_python2-daemon() {
+  depends=(python2 python2-lockfile)
+
+  cd "$srcdir/python-daemon-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE.ASF-2 "$pkgdir/usr/share/licenses/$pkgname/LICENSE.ASF-2"
+  install -Dm644 LICENSE.GPL-3 "$pkgdir/usr/share/licenses/$pkgname/LICENSE.GPL-3"
+}


Property changes on: python-daemon/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property