[arch-commits] Commit in lib32-libdrm/repos (2 files)

[Laurent Carlier]

    Date: Thursday, January 22, 2015 @ 07:44:40
  Author: lcarlier
Revision: 126400

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libdrm/repos/multilib-testing-x86_64/
  lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 126399, lib32-libdrm/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: lib32-libdrm/repos/multilib-testing-x86_64/PKGBUILD (from rev 126399, lib32-libdrm/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2015-01-22 06:44:40 UTC (rev 126400)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+_pkgbasename=libdrm
+pkgname=lib32-$_pkgbasename
+pkgver=2.4.59
+pkgrel=1
+pkgdesc="Userspace interface to kernel DRM services (32-bit)"
+arch=(x86_64)
+license=('custom')
+depends=('lib32-libpciaccess' $_pkgbasename)
+makedepends=(gcc-multilib)
+options=('!libtool')
+url="http://dri.freedesktop.org/"
+source=(http://dri.freedesktop.org/${_pkgbasename}/${_pkgbasename}-${pkgver}.tar.bz2{,.sig})
+sha256sums=('68d26e1fd85582f4243d66864f9b43ca4ee93662825de32b5506fc8e181ea41b'
+            SKIP)
+validpgpkeys=('B97BD6A80CAC4981091AE547FE558C72A67013C3') # Maarten Lankhorst <maarten.lankhorst at canonical.com>
+
+build() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+  # pthread is useless in Linux
+  sed -i "/pthread-stubs/d" configure.ac
+  autoreconf --force --install
+
+  ./configure --prefix=/usr --libdir=/usr/lib32 \
+      --enable-udev 
+
+  make
+}
+
+package() {
+  cd "${srcdir}/${_pkgbasename}-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install
+
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+  mkdir -p "$pkgdir/usr/share/licenses"
+  ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
+}
+