[arch-commits] Commit in (4 files)

[Christian Hesse]

    Date: Tuesday, June 2, 2015 @ 15:08:00
  Author: eworm
Revision: 134529

initial import for libykneomgr

Added:
  libykneomgr/
  libykneomgr/repos/
  libykneomgr/trunk/
  libykneomgr/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: libykneomgr/trunk/PKGBUILD
===================================================================
--- libykneomgr/trunk/PKGBUILD	                        (rev 0)
+++ libykneomgr/trunk/PKGBUILD	2015-06-02 13:08:00 UTC (rev 134529)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Christian Hesse <mail at eworm.de>
+
+pkgname=libykneomgr
+pkgver=0.1.7
+pkgrel=2
+pkgdesc="Yubico YubiKey NEO Manager C Library"
+arch=('i686' 'x86_64')
+url="https://github.com/Yubico/libykneomgr"
+license=('BSD')
+depends=('pcsclite' 'ccid' 'libzip')
+makedepends=('git' 'gengetopt' 'help2man')
+source=("git://github.com/Yubico/libykneomgr.git#tag=libykneomgr-${pkgver}")
+sha256sums=('SKIP')
+
+build() {
+	cd libykneomgr/
+
+	touch ChangeLog
+	autoreconf -fi
+	./configure --prefix=/usr
+	make
+}
+
+check() {
+	cd libykneomgr/
+
+	make check
+}
+
+package() {
+	cd libykneomgr/
+
+	install -D -m0644 COPYING "${pkgdir}/usr/share/licenses/libykneomgr/COPYING"
+	install -D -m0644 README "${pkgdir}/usr/share/doc/libykneomgr/README"
+	make DESTDIR="${pkgdir}/" install
+}
+


Property changes on: libykneomgr/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property