[arch-commits] Commit in (5 files)

[Levente Polyak]

    Date: Saturday, June 6, 2015 @ 18:08:21
  Author: anthraxx
Revision: 134906

addpkg hydra 8.1-3

Added:
  hydra/
  hydra/repos/
  hydra/trunk/
  hydra/trunk/PKGBUILD
  hydra/trunk/fix-locations.patch

---------------------+
 PKGBUILD            |   43 ++++++++++++++++++++++++++++++++++++++++
 fix-locations.patch |   53 ++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

Added: hydra/trunk/PKGBUILD
===================================================================
--- hydra/trunk/PKGBUILD	                        (rev 0)
+++ hydra/trunk/PKGBUILD	2015-06-06 16:08:21 UTC (rev 134906)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Rudy Matela <rudy at matela.com.br>
+# Contributor: Bartek Piotrowski <barthalion at gmail.com>
+# Contributor: Thomas S Hatch <thatch45 at gmail dot com>
+# Contributor: pootzko <pootzko at gmail.com>
+# Contributor: Jinx <jinxware at gmail.com>
+# Contributor: Timothée Ravier <tim at siosm.fr>
+ 
+pkgname=hydra
+pkgver=8.1
+pkgrel=3
+pkgdesc='A very fast network logon cracker which support many different services'
+url='http://www.thc.org/thc-hydra/'
+arch=('i686' 'x86_64')
+license=('GPL3')
+depends=('postgresql-libs' 'subversion' 'libssh' 'libmariadbclient' 'libidn' 'libfbclient' 'afpfs-ng')
+optdepends=(
+  'gtk2: graphical front-end (xhydra)'
+)
+makedepends=('gtk2')
+source=(${pkgname}-${pkgver}.tar.gz::http://www.thc.org/releases/${pkgname}-${pkgver}.tar.gz
+        fix-locations.patch)
+sha512sums=('7608dd365865e5976bea446faedaad9f0334e7572fd0ee47a601c471471fc7c8a922c7114f4df08705b34b29144d3a6552e66148adf6b0f92c67301119c94959'
+            '229fdaff59c6970a030ec81a78a2d34861a6caa947e7c2f6f9186cfd3bc0bf35ec96deadaae58ff1eaa45574f268fa5d9b9688df8c033fcee35ddeb302fb2069')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  patch -p1 < ../fix-locations.patch
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  ./configure --prefix=/usr
+  make
+}
+ 
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" MANDIR="/share/man/man1" DATADIR="/share/${pkgname}" install
+  install -Dm 644 README "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+# vim:set ts=2 sw=2 et:

Added: hydra/trunk/fix-locations.patch
===================================================================
--- hydra/trunk/fix-locations.patch	                        (rev 0)
+++ hydra/trunk/fix-locations.patch	2015-06-06 16:08:21 UTC (rev 134906)
@@ -0,0 +1,53 @@
+From 2c49f3ee2d9bac505543548301872fd0f36f31bc Mon Sep 17 00:00:00 2001
+From: anthraxx <levente at leventepolyak.net>
+Date: Sat, 6 Jun 2015 17:49:45 +0200
+Subject: [PATCH] configurable locations
+
+---
+ Makefile.am | 23 +++++++++++++----------
+ 1 file changed, 13 insertions(+), 10 deletions(-)
+
+diff --git a/Makefile.am b/Makefile.am
+index 89fb354..8a6f200 100644
+--- a/Makefile.am
++++ b/Makefile.am
+@@ -4,7 +4,10 @@
+ OPTS=-I. -O3
+ # -Wall -g -pedantic
+ LIBS=-lm
+-DIR=/bin
++BINDIR = /bin
++MANDIR ?= /man/man1
++DATADIR ?= /etc
++DESTDIR ?=
+ 
+ SRC = hydra-vnc.c hydra-pcnfs.c hydra-rexec.c hydra-nntp.c hydra-socks5.c \
+       hydra-telnet.c hydra-cisco.c hydra-http.c hydra-ftp.c hydra-imap.c \
+@@ -57,15 +60,15 @@ strip:	all
+ 	-echo OK > /dev/null && test -x xhydra && strip xhydra || echo OK > /dev/null
+ 
+ install:	strip
+-	-mkdir -p $(PREFIX)$(DIR)
+-	cp -f hydra-wizard.sh $(BINS) $(PREFIX)$(DIR) && cd $(PREFIX)$(DIR) && chmod 755 hydra-wizard.sh $(BINS)
+-	-echo OK > /dev/null && test -x xhydra && cp xhydra $(PREFIX)$(DIR) && cd $(PREFIX)$(DIR) && chmod 755 xhydra || echo OK > /dev/null
+-	-sed -e "s|^INSTALLDIR=.*|INSTALLDIR="$(PREFIX)"|" dpl4hydra.sh > $(PREFIX)/bin/dpl4hydra.sh
+-	-chmod 755 $(PREFIX)/bin/dpl4hydra.sh
+-	-mkdir -p $(PREFIX)/etc/
+-	-cp -f *.csv $(PREFIX)/etc/
+-	-mkdir -p $(PREFIX)/man/man1
+-	-cp -f hydra.1 xhydra.1 pw-inspector.1 $(PREFIX)/man/man1
++	-mkdir -p $(DESTDIR)$(PREFIX)$(BINDIR)
++	cp -f hydra-wizard.sh $(BINS) $(DESTDIR)$(PREFIX)$(BINDIR) && cd $(DESTDIR)$(PREFIX)$(BINDIR) && chmod 755 hydra-wizard.sh $(BINS)
++	-echo OK > /dev/null && test -x xhydra && cp xhydra $(DESTDIR)$(PREFIX)$(BINDIR) && cd $(DESTDIR)$(PREFIX)$(BINDIR) && chmod 755 xhydra || echo OK > /dev/null
++	-sed -e "s|^INSTALLDIR=.*|INSTALLDIR="$(PREFIX)"|" dpl4hydra.sh | sed -e "s|^LOCATION=.*|LOCATION="$(DATADIR)"|" > $(DESTDIR)$(PREFIX)$(BINDIR)/dpl4hydra.sh
++	-chmod 755 $(DESTDIR)$(PREFIX)$(BINDIR)/dpl4hydra.sh
++	-mkdir -p $(DESTDIR)$(PREFIX)$(DATADIR)
++	-cp -f *.csv $(DESTDIR)$(PREFIX)$(DATADIR)
++	-mkdir -p $(DESTDIR)$(PREFIX)$(MANDIR)
++	-cp -f hydra.1 xhydra.1 pw-inspector.1 $(DESTDIR)$(PREFIX)$(MANDIR)
+ 
+ clean:
+ 	rm -rf xhydra pw-inspector hydra *.o core *.core *.stackdump *~ Makefile.in Makefile dev_rfc hydra.restore arm/*.ipk arm/ipkg/usr/bin/* hydra-gtk/src/*.o hydra-gtk/src/xhydra hydra-gtk/stamp-h hydra-gtk/config.status hydra-gtk/errors hydra-gtk/config.log hydra-gtk/src/.deps hydra-gtk/src/Makefile hydra-gtk/Makefile
+-- 
+2.4.2
+