[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, May 8, 2015 @ 11:58:36
  Author: fyan
Revision: 132946

addpkg: python-queuelib 1.2.2-3

Added:
  python-queuelib/
  python-queuelib/repos/
  python-queuelib/trunk/
  python-queuelib/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: python-queuelib/trunk/PKGBUILD
===================================================================
--- python-queuelib/trunk/PKGBUILD	                        (rev 0)
+++ python-queuelib/trunk/PKGBUILD	2015-05-08 09:58:36 UTC (rev 132946)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: PyroDevil <p dot devil at gmail dot com>
+
+pkgbase=python-queuelib
+pkgname=('python2-queuelib' 'python-queuelib')
+pkgver=1.2.2
+pkgrel=3
+pkgdesc="Collection of persistent (disk-based) queues."
+arch=('any')
+license=('BSD')
+url="http://scrapy.org"
+makedepends=('git' 'python-setuptools' 'python2-setuptools')
+checkdepends=('python-nose' 'python2-nose')
+# options=(!emptydirs)
+source=("git+https://github.com/scrapy/queuelib.git#tag=v${pkgver}")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a queuelib{,-py2}
+}
+
+check() {
+  cd "$srcdir/queuelib"
+  nosetests3
+
+  cd "$srcdir/queuelib-py2"
+  nosetests2
+}
+
+package_python-queuelib() {
+  depends=('python')
+
+  cd "${srcdir}/queuelib"
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -D -m644 "README.rst" "${pkgdir}/usr/share/doc/${pkgname}/README.rst"
+}
+
+package_python2-queuelib() {
+  depends=('python2')
+
+  cd "${srcdir}/queuelib-py2"
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -D -m644 "README.rst" "${pkgdir}/usr/share/doc/${pkgname}/README.rst"
+}


Property changes on: python-queuelib/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property