[arch-commits] Commit in (5 files)
Martin Wimpress
flexiondotorg at archlinux.org
Sat May 9 14:22:27 UTC 2015
Date: Saturday, May 9, 2015 @ 16:22:26
Author: flexiondotorg
Revision: 133074
Added atril-gtk3
Added:
atril-gtk3/
atril-gtk3/repos/
atril-gtk3/trunk/
atril-gtk3/trunk/PKGBUILD
atril-gtk3/trunk/atril.install
---------------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
atril.install | 13 +++++++++++++
2 files changed, 65 insertions(+)
Added: atril-gtk3/trunk/PKGBUILD
===================================================================
--- atril-gtk3/trunk/PKGBUILD (rev 0)
+++ atril-gtk3/trunk/PKGBUILD 2015-05-09 14:22:26 UTC (rev 133074)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer : Martin Wimpress <code at flexion.org>
+
+_ver=1.10
+_pkgbase=atril
+pkgname=(${_pkgbase}-gtk3)
+pkgver=${_ver}.0
+pkgrel=1
+pkgdesc="MATE document viewer (GTK3 version [EXPERIMENTAL])"
+url="http://mate-desktop.org"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('dconf' 'dbus' 'desktop-file-utils' 'gtk3' 'libsecret' 'libsm' 'libspectre'
+ 'mate-desktop-gtk3>=1.10' 'mate-icon-theme' 'poppler-glib' 'webkitgtk' 'zlib')
+makedepends=('caja-gtk3>=1.10' 'djvulibre' 'gobject-introspection' 'libgxps'
+ 'mate-common' 'texlive-bin' 'yelp-tools')
+optdepends=('caja-gtk3: Document Properties extension'
+ 'djvulibre: DjVu support'
+ 'libgxps: XPS support'
+ 'p7zip: cbz and cb7 compressed comic books'
+ 'texlive-bin: DVI support'
+ 'unrar: cbr compressed comic books'
+ 'yelp: for reading MATE help documents')
+groups=('mate-extra-gtk3')
+conflicts=("${_pkgbase}")
+source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
+sha1sums=('7abd5b9310d88cb5da05248f1c55bb9ac069ac28')
+install=${_pkgbase}.install
+
+build() {
+ cd "${srcdir}/${_pkgbase}-${pkgver}"
+ ./configure \
+ --prefix=/usr \
+ --libexecdir=/usr/lib/${_pkgbase} \
+ --with-gtk=3.0 \
+ --enable-gtk-doc \
+ --enable-djvu \
+ --enable-dvi \
+ --enable-epub \
+ --enable-t1lib \
+ --enable-pixbuf \
+ --enable-comics \
+ --enable-xps \
+ --enable-introspection \
+ --disable-static
+ make
+}
+
+package() {
+ cd "${srcdir}/${_pkgbase}-${pkgver}"
+ make DESTDIR="${pkgdir}" install
+}
Property changes on: atril-gtk3/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: atril-gtk3/trunk/atril.install
===================================================================
--- atril-gtk3/trunk/atril.install (rev 0)
+++ atril-gtk3/trunk/atril.install 2015-05-09 14:22:26 UTC (rev 133074)
@@ -0,0 +1,13 @@
+post_install() {
+ glib-compile-schemas /usr/share/glib-2.0/schemas/
+ gtk-update-icon-cache -q -t -f /usr/share/icons/hicolor
+ update-desktop-database -q
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
More information about the arch-commits
mailing list