[arch-commits] Commit in python-scipy/repos/community-i686 (PKGBUILD)
Jelle van der Waa
jelle at archlinux.org
Sun Nov 1 20:23:12 UTC 2015
Date: Sunday, November 1, 2015 @ 21:23:12
Author: jelle
Revision: 145480
archrelease: copy trunk to community-i686
Added:
python-scipy/repos/community-i686/PKGBUILD
(from rev 145479, python-scipy/trunk/PKGBUILD)
----------+
PKGBUILD | 93 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 93 insertions(+)
Copied: python-scipy/repos/community-i686/PKGBUILD (from rev 145479, python-scipy/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2015-11-01 20:23:12 UTC (rev 145480)
@@ -0,0 +1,93 @@
+# Maintainer: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+
+pkgname=('python-scipy' 'python2-scipy')
+pkgver=0.16.1
+pkgrel=1
+pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
+arch=('i686' 'x86_64')
+url="http://www.scipy.org/"
+license=('BSD')
+makedepends=('gcc-fortran' 'python-numpy' 'python2-numpy' 'python-setuptools' 'python2-setuptools')
+checkdepends=('python-nose' 'python2-nose')
+source=("https://pypi.python.org/packages/source/s/scipy/scipy-${pkgver}.tar.gz"{,.asc})
+validpgpkeys=('BFE95DF198689E30AFF4A1CDEDBEA378BF1A5EBD')
+md5sums=('967cdb8588a4249f820344d8264a2143'
+ 'SKIP')
+
+build() {
+ export LDFLAGS="-Wall -shared"
+
+ # 2 builds
+ cp -r scipy-${pkgver} scipy-${pkgver}-py2
+
+ # build for python3
+ cd scipy-${pkgver}
+ python3 setup.py config_fc --fcompiler=gnu95 build
+
+ # build for python2
+ cd ../scipy-${pkgver}-py2
+
+ for file in $(find . -name '*.py' -print); do
+ sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
+ sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
+ done
+
+ python2 setup.py config_fc --fcompiler=gnu95 build
+}
+
+check() {
+ # we need to do a temp install so we can import scipy
+ # also, the tests must not be run from the scipy source directory
+ export LDFLAGS="-Wall -shared"
+
+ cd ${srcdir}/scipy-${pkgver}
+ python3 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root=${srcdir}/test --optimize=1
+ export PYTHONPATH=${srcdir}/test/usr/lib/python3.5/site-packages
+ cd ${srcdir}
+ python -c "from scipy import test; test('full')"
+
+ cd ${srcdir}/scipy-${pkgver}-py2
+ python2 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root=${srcdir}/test --optimize=1
+ export PYTHONPATH=${srcdir}/test/usr/lib/python2.7/site-packages
+ cd ${srcdir}
+ python2 -c "from scipy import test; test('full')"
+}
+
+package_python-scipy() {
+ depends=('python-numpy')
+ provides=('python3-scipy' 'scipy')
+ optdepends=('python-pillow: for image saving module')
+
+ cd scipy-${pkgver}
+ export LDFLAGS="-Wall -shared"
+
+ python3 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root=${pkgdir} --optimize=1
+
+ install -Dm644 LICENSE.txt \
+ "${pkgdir}/usr/share/licenses/python-scipy/LICENSE"
+}
+
+package_python2-scipy() {
+ depends=('python2-numpy')
+ optdepends=('python2-pillow: for image saving module')
+ conflicts=('python-scipy<0.9.0')
+
+ cd scipy-${pkgver}-py2
+ export LDFLAGS="-Wall -shared"
+
+ python2 setup.py config_fc --fcompiler=gnu95 install \
+ --prefix=/usr --root=${pkgdir} --optimize=1
+
+ install -Dm644 LICENSE.txt \
+ "${pkgdir}/usr/share/licenses/python2-scipy/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list