[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, November 3, 2015 @ 06:39:09
  Author: fyan
Revision: 145715

addpkg: python-persistent 4.1.1-1

Added:
  python-persistent/
  python-persistent/repos/
  python-persistent/trunk/
  python-persistent/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-persistent/trunk/PKGBUILD
===================================================================
--- python-persistent/trunk/PKGBUILD	                        (rev 0)
+++ python-persistent/trunk/PKGBUILD	2015-11-03 05:39:09 UTC (rev 145715)
@@ -0,0 +1,50 @@
+# $Id: PKGBUILD 141139 2015-09-20 03:14:59Z fyan $
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-persistent
+pkgname=('python-persistent' 'python2-persistent')
+pkgver=4.1.1
+pkgrel=1
+pkgdesc="Translucent persistent objects"
+arch=('i686' 'x86_64')
+license=('ZPL')
+url="http://www.zope.org/Products/ZODB"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/zopefoundation/persistent.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a persistent{,-py2}
+}
+
+build() {
+  cd "$srcdir/persistent"
+  python setup.py build
+
+  cd "$srcdir/persistent-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/persistent"
+  nosetests3
+
+  cd "$srcdir/persistent-py2"
+  nosetests2
+}
+
+package_python-persistent() {
+  depends=('python-zope-interface')
+
+  cd persistent
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-persistent() {
+  depends=('python2-zope-interface')
+
+  cd persistent-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}