[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Tue Nov 3 06:37:58 UTC 2015
Date: Tuesday, November 3, 2015 @ 07:37:57
Author: fyan
Revision: 145732
addpkg: python-zope-copy 4.0.3-1
Added:
python-zope-copy/
python-zope-copy/repos/
python-zope-copy/trunk/
python-zope-copy/trunk/PKGBUILD
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Added: python-zope-copy/trunk/PKGBUILD
===================================================================
--- python-zope-copy/trunk/PKGBUILD (rev 0)
+++ python-zope-copy/trunk/PKGBUILD 2015-11-03 06:37:57 UTC (rev 145732)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-copy' 'python2-zope-copy')
+pkgver=4.0.3
+pkgrel=1
+pkgdesc="Pluggable object copying mechanism"
+arch=('any')
+url="https://github.com/zopefoundation/zope.copy"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+ 'python2-zope-interface' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-zope-testing' 'python2-zope-testing'
+ 'python-zope-location' 'python2-zope-location')
+source=("git+https://github.com/zopefoundation/zope.copy.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+ cp -a zope.copy{,-py2}
+}
+
+build() {
+ cd "$srcdir/zope.copy"
+ python setup.py build
+
+ cd "$srcdir/zope.copy-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/zope.copy"
+ nosetests3
+
+ cd "$srcdir/zope.copy-py2"
+ nosetests2
+}
+
+package_python-zope-copy() {
+ depends=('python-setuptools' 'python-zope-interface')
+
+ cd "$srcdir/zope.copy"
+ python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-copy() {
+ depends=('python2-setuptools' 'python2-zope-interface')
+
+ cd "$srcdir/zope.copy-py2"
+ python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:
Property changes on: python-zope-copy/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list