[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, November 3, 2015 @ 09:00:49
  Author: fyan
Revision: 145748

addpkg: python-testtools 1.8.0-1

Added:
  python-testtools/
  python-testtools/repos/
  python-testtools/trunk/
  python-testtools/trunk/PKGBUILD

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Added: python-testtools/trunk/PKGBUILD
===================================================================
--- python-testtools/trunk/PKGBUILD	                        (rev 0)
+++ python-testtools/trunk/PKGBUILD	2015-11-03 08:00:49 UTC (rev 145748)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-testtools
+pkgname=('python-testtools' 'python2-testtools')
+pkgver=1.8.0
+pkgrel=1
+pkgdesc="Extensions to the Python standard library unit testing framework"
+arch=('any')
+license=('MIT')
+url="https://github.com/testing-cabal/testtools"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-yaml' 'python2-yaml'\
+             'git' 'python-pbr' 'python2-pbr' 'python-extras' 'python2-extras'
+             'python-mimeparse' 'python2-mimeparse' 'python2-traceback2')
+checkdepends=('python-nose' 'python2-nose' 'python-mock' 'python2-mock')
+source=("git+https://github.com/testing-cabal/testtools.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  # Since we are always latest...
+  sed -i 's|unittest2|unittest|' testtools/testtools/tests/test_run.py testtools/testtools/tests/test_testsuite.py testtools/testtools/tests/test_deferredruntest.py
+
+  cp -a testtools{,-py2}
+
+  # These are for python 2.x and old python 3.x only
+  sed -i 's|import linecache2 as linecache|import linecache|' testtools/testtools/tests/test_compat.py
+  sed -i "s|traceback = try_import('traceback2')|import traceback|" testtools/testtools/content.py
+}
+
+build() {
+  cd "$srcdir/testtools"
+  python setup.py build
+
+  cd "$srcdir/testtools-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/testtools"
+  python -m testtools.run testtools.tests.test_suite
+
+  cd "$srcdir/testtools-py2"
+  python2 -m testtools.run testtools.tests.test_suite
+}
+
+package_python-testtools() {
+  depends=('python-pbr' 'python-extras' 'python-mimeparse')
+
+  cd testtools
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-testtools() {
+  depends=('python2-pbr' 'python2-extras' 'python2-mimeparse' 'python2-traceback2')
+
+  cd testtools-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-testtools/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property