[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Tue Nov 3 08:42:42 UTC 2015
Date: Tuesday, November 3, 2015 @ 09:42:42
Author: fyan
Revision: 145757
addpkg: python-testscenarios 0.5.0-1
Added:
python-testscenarios/
python-testscenarios/repos/
python-testscenarios/trunk/
python-testscenarios/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: python-testscenarios/trunk/PKGBUILD
===================================================================
--- python-testscenarios/trunk/PKGBUILD (rev 0)
+++ python-testscenarios/trunk/PKGBUILD 2015-11-03 08:42:42 UTC (rev 145757)
@@ -0,0 +1,49 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-testscenarios
+pkgname=('python-testscenarios' 'python2-testscenarios')
+pkgver=0.5.0
+pkgrel=1
+pkgdesc="Testscenarios, a pyunit extension for dependency injection"
+arch=('any')
+license=('Apache')
+url="https://launchpad.net/testscenarios"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pbr' 'python2-pbr'
+ 'python-testtools' 'python2-testtools')
+source=("https://pypi.python.org/packages/source/t/testscenarios/testscenarios-$pkgver.tar.gz")
+sha512sums=('f08b868babf504482369c5cb945d3e95bca1cc00f92d5013f6898c488051be0c26dc49aaabcef362aea45450a8d041d9826fb6b5c848beec013fb102d6935521')
+
+prepare() {
+ cp -a testscenarios-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir/testscenarios-$pkgver"
+ python setup.py build
+
+ cd "$srcdir/testscenarios-$pkgver-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/testscenarios-$pkgver"
+ python -m testtools.run testscenarios.test_suite
+
+ cd "$srcdir/testscenarios-$pkgver-py2"
+ python2 -m testtools.run testscenarios.test_suite
+}
+
+package_python-testscenarios() {
+ depends=('python-testtools')
+
+ cd testscenarios-$pkgver
+ python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-testscenarios() {
+ depends=('python2-testtools')
+
+ cd testscenarios-$pkgver-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+}
Property changes on: python-testscenarios/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list