[arch-commits] Commit in python-zope-testrunner/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 3, 2015 @ 10:12:06
  Author: fyan
Revision: 145768

archrelease: copy trunk to community-any

Added:
  python-zope-testrunner/repos/community-any/
  python-zope-testrunner/repos/community-any/PKGBUILD
    (from rev 145767, python-zope-testrunner/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: python-zope-testrunner/repos/community-any/PKGBUILD (from rev 145767, python-zope-testrunner/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-11-03 09:12:06 UTC (rev 145768)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-testrunner' 'python2-zope-testrunner')
+pkgver=4.4.9
+pkgrel=1
+pkgdesc="Zope testrunner script"
+arch=('any')
+url="https://github.com/zopefoundation/zope.testrunner"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'python-zope-exceptions' 'python2-zope-exceptions'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-zope-testing' 'python2-zope-testing'
+              'python2-subunit')
+source=("git+https://github.com/zopefoundation/zope.testrunner.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.testrunner{,-py2}
+}
+
+build() {
+  cd "$srcdir/zope.testrunner"
+  python setup.py build
+
+  cd "$srcdir/zope.testrunner-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/zope.testrunner"
+  # https://github.com/zopefoundation/zope.testrunner/issues/30
+  python setup.py test || warning "Tests failed"
+
+  cd "$srcdir/zope.testrunner-py2"
+  python2 setup.py test
+}
+
+package_python-zope-testrunner() {
+  depends=('python-setuptools' 'python-zope-interface' 'python-zope-exceptions' 'python-six')
+
+  cd "$srcdir/zope.testrunner"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-testrunner() {
+  depends=('python2-setuptools' 'python2-zope-interface' 'python2-zope-exceptions' 'python2-six')
+
+  cd "$srcdir/zope.testrunner-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+
+  mv "$pkgdir/usr/bin/zope-testrunner"{,2}
+}
+
+# vim:set ts=2 sw=2 et: