[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, November 3, 2015 @ 15:43:06
  Author: fyan
Revision: 145797

addpkg: python-zope-deprecation 4.1.2-1

Added:
  python-zope-deprecation/
  python-zope-deprecation/repos/
  python-zope-deprecation/trunk/
  python-zope-deprecation/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-zope-deprecation/trunk/PKGBUILD
===================================================================
--- python-zope-deprecation/trunk/PKGBUILD	                        (rev 0)
+++ python-zope-deprecation/trunk/PKGBUILD	2015-11-03 14:43:06 UTC (rev 145797)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=('python-zope-deprecation' 'python2-zope-deprecation')
+pkgver=4.1.2
+pkgrel=1
+pkgdesc="Zope Deprecation Infrastructure"
+arch=('any')
+url="https://github.com/zopefoundation/zope.deprecation"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/zopefoundation/zope.deprecation.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.deprecation{,-py2}
+}
+
+build() {
+  cd "$srcdir/zope.deprecation"
+  python setup.py build
+
+  cd "$srcdir/zope.deprecation-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/zope.deprecation"
+  nosetests3
+
+  cd "$srcdir/zope.deprecation-py2"
+  nosetests2
+}
+
+package_python-zope-deprecation() {
+  depends=('python-setuptools')
+
+  cd "$srcdir/zope.deprecation"
+  python setup.py install --root="$pkgdir/" --optimize=1
+}
+
+package_python2-zope-deprecation() {
+  depends=('python2-setuptools')
+
+  cd "$srcdir/zope.deprecation-py2"
+  python2 setup.py install --root="$pkgdir/" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: python-zope-deprecation/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property