[arch-commits] Commit in volatility/repos (community-any community-any/PKGBUILD)

[Levente Polyak]

    Date: Wednesday, November 4, 2015 @ 16:36:11
  Author: anthraxx
Revision: 145984

archrelease: copy trunk to community-any

Added:
  volatility/repos/community-any/
  volatility/repos/community-any/PKGBUILD
    (from rev 145983, volatility/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: volatility/repos/community-any/PKGBUILD (from rev 145983, volatility/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-11-04 15:36:11 UTC (rev 145984)
@@ -0,0 +1,43 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Limao Luo <luolimao+AUR at gmail.com>
+# Contributor: Wes Brown <wesbrown18 at gmail.com>
+
+pkgname=volatility
+pkgver=2.5
+pkgrel=1
+pkgdesc="Advanced memory forensics framework"
+url="https://github.com/volatilityfoundation/volatility/wiki"
+arch=('any')
+license=('GPL2')
+depends=('distorm' 'python2-crypto' 'python2-ujson')
+optdepends=(
+  'python2-yara: classify malware support'
+  'python2-pillow: screenshots plugin support'
+  'python2-pytz: timezone conversion support'
+  'ipython2: enhanced volshell support'
+  'libforensic1394: firewire live analysis support'
+  'libraw1394: alternative firewire live analysis support'
+  'python2-openpyxl: Excel xlsx/xlsm files support'
+)
+makedepends=('python2-setuptools')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/volatilityfoundation/${pkgname}/archive/${pkgver}.tar.gz)
+sha512sums=('137a0727106beb2321f956c53f304ae4ff00397da935d490c595e7b657bdec348cd5ac4472ba9da8c7ce2a1a8559e33535df7b68efb815084217f131cb044632')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  sed -e 's/env python$/env python2/g' -i tools/vtype_diff.py
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+
+  python2 setup.py install -O1 --prefix=/usr --root="${pkgdir}"
+  ln -s /usr/bin/vol.py "${pkgdir}/usr/bin/${pkgname}"
+
+  install -d "${pkgdir}/usr/share/${pkgname}"
+  mv "${pkgdir}/usr/tools" "${pkgdir}/usr/share/${pkgname}"
+  mv "${pkgdir}/usr/contrib" "${pkgdir}/usr/share/${pkgname}"
+  install -Dm 644 README.txt "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+# vim: ts=2 sw=2 et: