[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, November 9, 2015 @ 16:15:34
  Author: fyan
Revision: 146431

addpkg: python-construct 2.5.2-1

Added:
  python-construct/
  python-construct/repos/
  python-construct/trunk/
  python-construct/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-construct/trunk/PKGBUILD
===================================================================
--- python-construct/trunk/PKGBUILD	                        (rev 0)
+++ python-construct/trunk/PKGBUILD	2015-11-09 15:15:34 UTC (rev 146431)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-construct
+pkgname=('python-construct' 'python2-construct')
+pkgver=2.5.2
+pkgrel=1
+pkgdesc="A powerful declarative parser/builder for binary data"
+arch=('any')
+license=('MIT')
+url="http://construct.readthedocs.org"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose')
+source=("git+https://github.com/construct/construct.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a construct{,-py2}
+}
+
+build() {
+  cd "$srcdir/construct"
+  python setup.py build
+
+  cd "$srcdir/construct-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/construct"
+  nosetests3 tests
+
+  cd "$srcdir/construct-py2"
+  nosetests2 tests
+}
+
+package_python-construct() {
+  depends=('python-six')
+
+  cd construct
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-construct() {
+  depends=('python2-six')
+
+  cd construct-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-construct/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property