[arch-commits] Commit in (4 files)

[Levente Polyak]

    Date: Friday, November 13, 2015 @ 16:49:15
  Author: anthraxx
Revision: 146723

addpkg: diffoscope 40-1

Added:
  diffoscope/
  diffoscope/repos/
  diffoscope/trunk/
  diffoscope/trunk/PKGBUILD

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Added: diffoscope/trunk/PKGBUILD
===================================================================
--- diffoscope/trunk/PKGBUILD	                        (rev 0)
+++ diffoscope/trunk/PKGBUILD	2015-11-13 15:49:15 UTC (rev 146723)
@@ -0,0 +1,60 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=diffoscope
+pkgver=40
+pkgrel=1
+pkgdesc='Tool for in-depth comparison of files, archives, and directories'
+url='https://diffoscope.org/'
+arch=('x86_64')
+license=('GPL3')
+depends=('python-magic' 'python-libarchive-c' 'python-setuptools')
+optdepends=(
+  'acl: access control list utilities support'
+  'binutils: binary utilities support'
+  'bzip2: bzip2 utilities support'
+  'cdrkit: ISO utilities support'
+  'cpio: cpio archive support'
+  'java-runtime: java utilities support'
+  'fontforge: bitmap font utilities support'
+  'gettext: GNU internationalization utilities support'
+  'ghc: haskell utilities support'
+  'gnupg: GNU privacy guard support'
+  'mono-tools: mono utilities support'
+  #'pdftk: PDF utilities support'
+  'poppler: PDF utilities support'
+  'sqlite: SQLite support'
+  'squashfs-tools: squashfs filesystem support'
+  'unzip: zip utilities support'
+  'gzip: gzip utilities support'
+  'tar: tar utilities support'
+  'vim: Vi IMproved (xxd) utilities support'
+  'xz: XZ and LZMA utilities support'
+)
+checkdepends=(
+  'python-pytest' 'acl' 'binutils' 'bzip2' 'cdrkit' 'cpio' 'java-runtime' 'fontforge' 'gettext' 'ghc' 'gnupg' 'mono-tools'
+  'poppler' 'sqlite' 'squashfs-tools' 'unzip' 'gzip' 'tar' 'vim' 'xz')
+source=(${pkgname}-${pkgver}.tar.xz::https://anonscm.debian.org/cgit/reproducible/${pkgname}.git/snapshot/${pkgname}-${pkgver}.tar.xz)
+sha512sums=('b40e042769cc87056bdde5306c8630043995c16bd4f5b28a51eba3fd08c06f4975ff82b4b19c9fd7b203c5fa7d541ba69c734c787bdae09f0bf35facc376f533')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  sed '/python-magic/d' -i setup.py
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  PYTHONPATH=".:${PYTHONPATH}" py.test
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}"
+  install -Dm 644 README.rst "${pkgdir}/usr/share/doc/${pkgname}/README"
+}
+
+# vim: ts=2 sw=2 et: