[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Sat Nov 14 04:05:00 UTC 2015
Date: Saturday, November 14, 2015 @ 05:05:00
Author: fyan
Revision: 146765
addpkg: python-parsedatetime 1.5.20151107-1
Added:
python-parsedatetime/
python-parsedatetime/repos/
python-parsedatetime/trunk/
python-parsedatetime/trunk/PKGBUILD
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Added: python-parsedatetime/trunk/PKGBUILD
===================================================================
--- python-parsedatetime/trunk/PKGBUILD (rev 0)
+++ python-parsedatetime/trunk/PKGBUILD 2015-11-14 04:05:00 UTC (rev 146765)
@@ -0,0 +1,56 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Hugo Osvaldo Barrera <hugo at barrera.io>
+# Contributor: Daniel M. Capella <polycitizen at gmail.com>
+# Contributor: Hugo Osvaldo Barrera <hugo at barrera.io>
+# Contributor: Limao Luo <luolimao+AUR at gmail.com>
+# Contributor: Jeremy Sands <cto at jeremysands.com>
+
+pkgbase=python-parsedatetime
+pkgname=('python-parsedatetime' 'python2-parsedatetime')
+pkgver=1.5.20151107
+_commit=cd5847e10d72d90d394f471f64f4e2d93de0b02d
+pkgrel=1
+pkgdesc="Parse human-readable date/time strings."
+arch=('any')
+license=('Apache')
+url='http://github.com/bear/parsedatetime'
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-pyicu' 'python2-pyicu'
+ 'python-coverage' 'python2-coverage')
+source=("git+https://github.com/bear/parsedatetime.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a parsedatetime{,-py2}
+}
+
+build() {
+ cd "$srcdir/parsedatetime"
+ python setup.py build
+
+ cd "$srcdir/parsedatetime-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/parsedatetime"
+ nosetests3
+
+ cd "$srcdir/parsedatetime-py2"
+ nosetests2
+}
+
+package_python-parsedatetime() {
+ depends=('python')
+
+ cd parsedatetime
+ python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-parsedatetime() {
+ depends=('python2')
+
+ cd parsedatetime-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+}
Property changes on: python-parsedatetime/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list