[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, November 14, 2015 @ 10:43:41
  Author: fyan
Revision: 146794

addpkg: python-chameleon 2.24-1

Added:
  python-chameleon/
  python-chameleon/repos/
  python-chameleon/trunk/
  python-chameleon/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: python-chameleon/trunk/PKGBUILD
===================================================================
--- python-chameleon/trunk/PKGBUILD	                        (rev 0)
+++ python-chameleon/trunk/PKGBUILD	2015-11-14 09:43:41 UTC (rev 146794)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-chameleon
+pkgname=('python-chameleon' 'python2-chameleon')
+pkgver=2.24
+pkgrel=1
+pkgdesc="Fast HTML/XML Template Compiler"
+arch=('any')
+license=('custom:BSD' 'ZPL')
+url="http://www.pagetemplates.org/"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/malthe/chameleon.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a chameleon{,-py2}
+}
+
+build() {
+  cd "$srcdir/chameleon"
+  python setup.py build
+
+  cd "$srcdir/chameleon-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/chameleon"
+  python setup.py test
+
+  cd "$srcdir/chameleon-py2"
+  python2 setup.py test
+}
+
+package_python-chameleon() {
+  depends=('python')
+
+  cd chameleon
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}
+
+package_python2-chameleon() {
+  depends=('python2')
+
+  cd chameleon-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}


Property changes on: python-chameleon/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property