[arch-commits] Commit in python-chameleon/repos (community-any community-any/PKGBUILD)

[Felix Yan]

    Date: Saturday, November 14, 2015 @ 10:44:04
  Author: fyan
Revision: 146795

archrelease: copy trunk to community-any

Added:
  python-chameleon/repos/community-any/
  python-chameleon/repos/community-any/PKGBUILD
    (from rev 146794, python-chameleon/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: python-chameleon/repos/community-any/PKGBUILD (from rev 146794, python-chameleon/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2015-11-14 09:44:04 UTC (rev 146795)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-chameleon
+pkgname=('python-chameleon' 'python2-chameleon')
+pkgver=2.24
+pkgrel=1
+pkgdesc="Fast HTML/XML Template Compiler"
+arch=('any')
+license=('custom:BSD' 'ZPL')
+url="http://www.pagetemplates.org/"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/malthe/chameleon.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a chameleon{,-py2}
+}
+
+build() {
+  cd "$srcdir/chameleon"
+  python setup.py build
+
+  cd "$srcdir/chameleon-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/chameleon"
+  python setup.py test
+
+  cd "$srcdir/chameleon-py2"
+  python2 setup.py test
+}
+
+package_python-chameleon() {
+  depends=('python')
+
+  cd chameleon
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}
+
+package_python2-chameleon() {
+  depends=('python2')
+
+  cd chameleon-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}