[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, November 18, 2015 @ 08:02:22
  Author: fyan
Revision: 147052

addpkg: python-pygithub 1.26.0-1

Added:
  python-pygithub/
  python-pygithub/repos/
  python-pygithub/trunk/
  python-pygithub/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-pygithub/trunk/PKGBUILD
===================================================================
--- python-pygithub/trunk/PKGBUILD	                        (rev 0)
+++ python-pygithub/trunk/PKGBUILD	2015-11-18 07:02:22 UTC (rev 147052)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pygithub
+pkgname=('python-pygithub' 'python2-pygithub')
+pkgver=1.26.0
+pkgrel=1
+pkgdesc="Use the full Github API v3"
+arch=('any')
+license=('LGPL')
+url="http://jacquev6.github.com/PyGithub"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/PyGithub/PyGithub.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a PyGithub{,-py2}
+}
+
+build() {
+  cd "$srcdir/PyGithub"
+  python setup.py build
+
+  cd "$srcdir/PyGithub-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/PyGithub"
+  python setup.py test
+
+  cd "$srcdir/PyGithub-py2"
+  python2 setup.py test
+}
+
+package_python-pygithub() {
+  depends=('python')
+
+  cd PyGithub
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-pygithub() {
+  depends=('python2')
+
+  cd PyGithub-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+}


Property changes on: python-pygithub/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property