[arch-commits] Commit in (3 files)
Antonio Rojas
arojas at archlinux.org
Fri Oct 2 14:18:52 UTC 2015
Date: Friday, October 2, 2015 @ 16:18:52
Author: arojas
Revision: 248272
Add libaccounts-qt4 package, still needed for kdepim4
Added:
libaccounts-qt4/
libaccounts-qt4/trunk/
libaccounts-qt4/trunk/PKGBUILD
----------+
PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
Added: libaccounts-qt4/trunk/PKGBUILD
===================================================================
--- libaccounts-qt4/trunk/PKGBUILD (rev 0)
+++ libaccounts-qt4/trunk/PKGBUILD 2015-10-02 14:18:52 UTC (rev 248272)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=libaccounts-qt4
+pkgdesc="Qt4-based client library for accessing the online accounts database"
+pkgver=1.13
+pkgrel=2
+arch=(i686 x86_64)
+url="https://gitlab.com/accounts-sso/libaccounts-qt"
+license=(LGPL)
+depends=(qt4 libaccounts-glib)
+makedepends=(doxygen)
+source=("https://gitlab.com/accounts-sso/libaccounts-qt/repository/archive.tar.bz2?ref=VERSION_$pkgver")
+sha1sums=('4b4043fef3e9b42023d5f1e415690bcb4017f820')
+
+prepare() {
+ mv libaccounts-qt-VERSION_$pkgver-* accounts-qt-$pkgver
+ cd accounts-qt-$pkgver
+ sed -i 's|SUBDIRS += Accounts tests|SUBDIRS += Accounts|' accounts-qt.pro
+
+ # Qt4 fix
+ sed -i 's|QHG_LOCATION = qhelpgenerator|QHG_LOCATION = qhelpgenerator-qt4|' doc/doxy.conf
+}
+
+build() {
+ cd accounts-qt-$pkgver
+ qmake-qt4 PREFIX=/usr LIBDIR=/usr/lib
+ make
+}
+
+package() {
+ cd accounts-qt-$pkgver
+ make INSTALL_ROOT="$pkgdir" install
+
+# Remove docs to fix conflicts
+ rm -r "${pkgdir}"/usr/share
+}
Property changes on: libaccounts-qt4/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list