[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, October 3, 2015 @ 05:53:10
  Author: fyan
Revision: 142835

addpkg: lib32-libva 1.6.1-1

Added:
  lib32-libva/
  lib32-libva/repos/
  lib32-libva/trunk/
  lib32-libva/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: lib32-libva/trunk/PKGBUILD
===================================================================
--- lib32-libva/trunk/PKGBUILD	                        (rev 0)
+++ lib32-libva/trunk/PKGBUILD	2015-10-03 03:53:10 UTC (rev 142835)
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
+# Contributor: kokoko3k <kokoko3k at gmail dot com>
+# Contributor: Ionut Biru <ibiru at archlinux dot org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux dot org>
+
+pkgname=lib32-libva
+pkgver=1.6.1
+pkgrel=1
+pkgdesc='Video Acceleration (VA) API for Linux (32-bit)'
+arch=('x86_64')
+url='http://freedesktop.org/wiki/Software/vaapi'
+license=('MIT')
+depends=('lib32-libdrm' 'lib32-libgl' 'lib32-wayland' 'lib32-libxext' 'lib32-libxfixes' 'libva')
+makedepends=('mesa' 'gcc-multilib')
+optdepends=('lib32-libva-vdpau-driver: vdpau back-end for nvidia'
+            'lib32-libva-intel-driver: back-end for intel cards')
+source=(http://freedesktop.org/software/vaapi/releases/libva/libva-${pkgver}.tar.bz2)
+sha512sums=('cd21c27b89c975cbf6cc77125625dca77332467b291536e0fa4640618871be9dbd1c51e7bd09d15b1af8dbd9166a29113f2dd10a50558ffa00d21161cb9d7958')
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+  cd "${pkgname#*-}-${pkgver}"
+  ./configure --prefix=/usr --libdir='/usr/lib32' 
+  make
+}
+
+package() {
+  cd "${pkgname#*-}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  rm -rfv "${pkgdir}/usr/"{include,bin}
+  install -m644 -D COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
+}


Property changes on: lib32-libva/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property