[arch-commits] Commit in python-requests/repos (3 files)
Felix Yan
fyan at archlinux.org
Tue Oct 6 16:14:03 UTC 2015
Date: Tuesday, October 6, 2015 @ 18:14:03
Author: fyan
Revision: 248426
archrelease: copy trunk to testing-any
Added:
python-requests/repos/testing-any/
python-requests/repos/testing-any/PKGBUILD
(from rev 248425, python-requests/trunk/PKGBUILD)
python-requests/repos/testing-any/certs.patch
(from rev 248425, python-requests/trunk/certs.patch)
-------------+
PKGBUILD | 71 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
certs.patch | 13 ++++++++++
2 files changed, 84 insertions(+)
Copied: python-requests/repos/testing-any/PKGBUILD (from rev 248425, python-requests/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD (rev 0)
+++ testing-any/PKGBUILD 2015-10-06 16:14:03 UTC (rev 248426)
@@ -0,0 +1,71 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-requests
+pkgname=('python-requests' 'python2-requests')
+pkgver=2.8.0
+pkgrel=1
+pkgdesc="Python HTTP for Humans"
+arch=('any')
+url="http://python-requests.org"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-chardet' 'python2-chardet'
+ 'python-urllib3' 'python2-urllib3')
+checkdepends=('python-pytest' 'python2-pytest')
+source=(http://pypi.python.org/packages/source/r/requests/requests-$pkgver.tar.gz
+ certs.patch)
+sha256sums=('b2f003589b60924909c0acde472590c5ea83906986a7a25b6f7929eb20923b7b'
+ 'e35e779d8640f35ea2ea51112f967d927b44d59483af4cd2c0945c84e79bb7c7')
+
+prepare() {
+ cd "$srcdir"/requests-$pkgver
+
+ patch -p1 -i "$srcdir"/certs.patch
+ sed -r 's#(\W|^)requests/cacert\.pem(\W|$)##' -i MANIFEST.in
+ rm -f requests/cacert.pem
+
+ rm -r requests/packages/{urllib3,chardet}
+ sed -e '/packages.chardet/d' \
+ -e '/packages.urllib3/d' \
+ -i setup.py
+
+ cd "$srcdir"
+ cp -a requests-$pkgver{,-py2}
+ find requests-$pkgver-py2 -name \*.py -exec sed -r 's|^#!(.*)python$|#!\1python2|' -i {} +
+}
+
+build() {
+ cd "$srcdir"/requests-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/requests-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/requests-$pkgver
+ test -f "$(python -m requests.certs)"
+ py.test
+
+ cd "$srcdir"/requests-$pkgver-py2
+ test -f "$(python2 -m requests.certs)"
+ py.test2
+}
+
+package_python-requests() {
+ depends=('python-urllib3' 'python-chardet')
+
+ cd "$srcdir"/requests-$pkgver
+ python setup.py install --skip-build -O1 --root="$pkgdir"
+ install -m0644 -D "LICENSE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-requests() {
+ depends=('python2-urllib3' 'python2-chardet')
+ optdepends=('python2-ndg-httpsclient: HTTPS requests with SNI support'
+ 'python2-grequests: asynchronous requests with gevent')
+
+ cd "$srcdir"/requests-$pkgver-py2
+ python2 setup.py install --skip-build -O1 --root="$pkgdir"
+}
Copied: python-requests/repos/testing-any/certs.patch (from rev 248425, python-requests/trunk/certs.patch)
===================================================================
--- testing-any/certs.patch (rev 0)
+++ testing-any/certs.patch 2015-10-06 16:14:03 UTC (rev 248426)
@@ -0,0 +1,13 @@
+diff --git a/requests/certs.py b/requests/certs.py
+index 07e6475..33db011 100644
+--- a/requests/certs.py
++++ b/requests/certs.py
+@@ -19,7 +19,7 @@ except ImportError:
+ def where():
+ """Return the preferred certificate bundle."""
+ # vendored bundle inside Requests
+- return os.path.join(os.path.dirname(__file__), 'cacert.pem')
++ return "/etc/ssl/certs/ca-certificates.crt"
+
+ if __name__ == '__main__':
+ print(where())
More information about the arch-commits
mailing list