[arch-commits] Commit in (3 files)

[Antonio Rojas]

    Date: Monday, October 12, 2015 @ 12:58:25
  Author: arojas
Revision: 143760

Add python-igraph (new sagemath dependency)

Added:
  python-igraph/
  python-igraph/trunk/
  python-igraph/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: python-igraph/trunk/PKGBUILD
===================================================================
--- python-igraph/trunk/PKGBUILD	                        (rev 0)
+++ python-igraph/trunk/PKGBUILD	2015-10-12 10:58:25 UTC (rev 143760)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Lukasz Pozarlik <lpozarlik at gmail.com>
+
+pkgbase=python-igraph
+pkgname=(python-igraph python2-igraph)
+pkgver=0.7.1.post6
+pkgrel=1
+url="http://igraph.org/python/"
+license=(GPL)
+arch=(i686 x86_64)
+makedepends=(python python2 igraph) 
+source="https://pypi.python.org/packages/source/p/$pkgbase/$pkgbase-$pkgver.tar.gz"
+md5sums=('a4c0b5960735b36adb5d3a40031cb7c0')
+
+prepare() {
+  cp -r $pkgbase-$pkgver{,-python2}
+
+  sed -e 's|/usr/bin/env python|/usr/bin/env/python2|g' -i $pkgbase-$pkgver-python2/igraph/vendor/texttable.py
+}
+
+build() {
+  cd $pkgbase-$pkgver
+  python setup.py build
+
+  cd ../$pkgbase-$pkgver-python2
+  python2 setup.py build
+}
+
+package_python-igraph() {
+  pkgdesc="Python bindings for the igraph library"
+  depends=(igraph python)
+
+  cd $pkgbase-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-igraph() {
+  pkgdesc="Python 2 bindings for the igraph library"
+  depends=(igraph python2)
+  conflicts=(python-igraph)
+
+  cd $pkgbase-$pkgver-python2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}


Property changes on: python-igraph/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property