[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, October 13, 2015 @ 16:09:27
  Author: fyan
Revision: 143916

addpkg: python-whoosh 2.7.0-1

Added:
  python-whoosh/
  python-whoosh/repos/
  python-whoosh/trunk/
  python-whoosh/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: python-whoosh/trunk/PKGBUILD
===================================================================
--- python-whoosh/trunk/PKGBUILD	                        (rev 0)
+++ python-whoosh/trunk/PKGBUILD	2015-10-13 14:09:27 UTC (rev 143916)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Samuel Littley <aur at toastwaffle.com>
+# Contributor: rnons <remotenonsense at gmail dot com>
+
+pkgbase=python-whoosh
+pkgname=(python-whoosh python2-whoosh)
+pkgver=2.7.0
+pkgrel=1
+pkgdesc="Fast, pure-Python full text indexing, search, and spell checking library"
+arch=('any')
+url="http://bitbucket.org/mchaput/whoosh/wiki/Home"
+license=("BSD")
+makedepends=('python-setuptools' 'python2-setuptools' 'mercurial')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("hg+https://bitbucket.org/mchaput/whoosh#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a whoosh{,-py2}
+}
+
+build() {
+  cd "$srcdir/whoosh"
+  python setup.py build
+
+  cd "$srcdir/whoosh-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/whoosh"
+  python setup.py ptr || warning "Tests failed"
+
+  cd "$srcdir/whoosh-py2"
+  python2 setup.py ptr || warning "Tests failed"
+}
+
+package_python-whoosh() {
+  depends=('python')
+
+  cd "${srcdir}/whoosh"
+  python setup.py install -O1 --root="${pkgdir}"
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}
+
+package_python2-whoosh() {
+  depends=('python2')
+
+  cd "${srcdir}/whoosh-py2"
+  python2 setup.py install -O1 --root="${pkgdir}"
+  install -D -m644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}


Property changes on: python-whoosh/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property