[arch-commits] Commit in (11 files)
Maxime Gauduin
alucryd at archlinux.org
Wed Oct 14 07:44:00 UTC 2015
Date: Wednesday, October 14, 2015 @ 09:44:00
Author: alucryd
Revision: 143983
Build lib32-gtk3 against lib32-librsvg
Added:
lib32-libcroco/
lib32-libcroco/lib32-librsvg/
lib32-libcroco/lib32-librsvg/.SRCINFO
lib32-libcroco/lib32-librsvg/PKGBUILD
lib32-libcroco/trunk/
lib32-libcroco/trunk/PKGBUILD
lib32-librsvg/
lib32-librsvg/trunk/
lib32-librsvg/trunk/PKGBUILD
lib32-librsvg/trunk/librsvg.install
Modified:
lib32-gtk3/trunk/PKGBUILD
---------------------------------------+
lib32-gtk3/trunk/PKGBUILD | 4 +-
lib32-libcroco/lib32-librsvg/.SRCINFO | 24 ++++++++++++++
lib32-libcroco/lib32-librsvg/PKGBUILD | 52 ++++++++++++++++++++++++++++++++
lib32-libcroco/trunk/PKGBUILD | 39 ++++++++++++++++++++++++
lib32-librsvg/trunk/PKGBUILD | 41 +++++++++++++++++++++++++
lib32-librsvg/trunk/librsvg.install | 13 ++++++++
6 files changed, 171 insertions(+), 2 deletions(-)
Modified: lib32-gtk3/trunk/PKGBUILD
===================================================================
--- lib32-gtk3/trunk/PKGBUILD 2015-10-14 07:37:11 UTC (rev 143982)
+++ lib32-gtk3/trunk/PKGBUILD 2015-10-14 07:44:00 UTC (rev 143983)
@@ -5,13 +5,13 @@
pkgname=lib32-gtk3
pkgver=3.18.2
-pkgrel=1
+pkgrel=2
pkgdesc='GObject-based multi-platform GUI toolkit (v3)'
arch=('x86_64')
license=('LGPL')
url='http://www.gtk.org/'
depends=('gtk3' 'lib32-at-spi2-atk' 'lib32-colord' 'lib32-gdk-pixbuf2'
- 'lib32-json-glib' 'lib32-libcups' 'lib32-libepoxy'
+ 'lib32-json-glib' 'lib32-libcups' 'lib32-libepoxy' 'lib32-librsvg'
'lib32-libxcomposite' 'lib32-libxcursor' 'lib32-libxinerama'
'lib32-libxkbcommon' 'lib32-libxrandr' 'lib32-pango' 'lib32-rest')
makedepends=('gcc-multilib' 'gobject-introspection')
Added: lib32-libcroco/lib32-librsvg/.SRCINFO
===================================================================
--- lib32-libcroco/lib32-librsvg/.SRCINFO (rev 0)
+++ lib32-libcroco/lib32-librsvg/.SRCINFO 2015-10-14 07:44:00 UTC (rev 143983)
@@ -0,0 +1,24 @@
+pkgbase = lib32-librsvg
+ pkgdesc = A SVG viewing library (32-bit)
+ pkgver = 2.40.11
+ pkgrel = 1
+ url = https://live.gnome.org/LibRsvg
+ arch = x86_64
+ license = LGPL
+ makedepends = gcc-multilib
+ makedepends = intltool
+ makedepends = gobject-introspection
+ makedepends = vala
+ makedepends = python2
+ depends = lib32-gdk-pixbuf2
+ depends = lib32-pango
+ depends = lib32-libcroco
+ depends = librsvg
+ options = !emptydirs
+ source = http://ftp.gnome.org/pub/gnome/sources/librsvg/2.40/librsvg-2.40.11.tar.xz
+ source = librsvg-gtk-optional.patch::https://bug712693.bugzilla-attachments.gnome.org/attachment.cgi?id=260258
+ sha256sums = 611ac0f544debd0c9bf1ef5509c990d218e83dd1d8c83297075c4b29796a2e02
+ sha256sums = 060ad4965c51d334da543970f959022d519bd3e714c1ee22c4cf9081e875c1e3
+
+pkgname = lib32-librsvg
+
Added: lib32-libcroco/lib32-librsvg/PKGBUILD
===================================================================
--- lib32-libcroco/lib32-librsvg/PKGBUILD (rev 0)
+++ lib32-libcroco/lib32-librsvg/PKGBUILD 2015-10-14 07:44:00 UTC (rev 143983)
@@ -0,0 +1,52 @@
+# Maintainer: jtts
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+_pkgbasename=librsvg
+pkgname=lib32-$_pkgbasename
+pkgver=2.40.11
+pkgrel=1
+#epoch=1
+pkgdesc="A SVG viewing library (32-bit)"
+arch=(x86_64)
+license=(LGPL)
+depends=(lib32-gdk-pixbuf2 lib32-pango lib32-libcroco $_pkgbasename)
+makedepends=(gcc-multilib intltool gobject-introspection vala python2)
+options=('!emptydirs')
+url="https://live.gnome.org/LibRsvg"
+#install=librsvg.install
+source=("http://ftp.gnome.org/pub/gnome/sources/$_pkgbasename/${pkgver:0:4}/$_pkgbasename-$pkgver.tar.xz"
+ librsvg-gtk-optional.patch::https://bug712693.bugzilla-attachments.gnome.org/attachment.cgi?id=260258)
+sha256sums=('611ac0f544debd0c9bf1ef5509c990d218e83dd1d8c83297075c4b29796a2e02'
+ '060ad4965c51d334da543970f959022d519bd3e714c1ee22c4cf9081e875c1e3')
+
+prepare() {
+ cd $_pkgbasename-$pkgver
+ sed -e s/configure.in/configure.ac/ -e s/GTK\ 3.0\:\ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ \ /GTK\+\ \$GTK3_REQUIRED\ or\ later\:\ \ \ \ \ \ \ \ \ \ \ / <../librsvg-gtk-optional.patch | patch -p1
+ autoconf
+ aclocal
+ automake
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
+
+ cd $_pkgbasename-$pkgver
+ ./configure --prefix=/usr --disable-static --enable-vala \
+ --libdir=/usr/lib32 \
+ --disable-gtk-doc \
+ --disable-gtk-doc-html \
+ --disable-gtk-doc-pdf \
+ --without-gtk3 \
+ --enable-introspection=yes
+ make
+}
+
+package() {
+ cd $_pkgbasename-$pkgver
+ make DESTDIR="$pkgdir" install
+
+ # remove unneeded stuff
+ rm -fr ${pkgdir}/{usr/{bin,include,share},etc}
+}
Added: lib32-libcroco/trunk/PKGBUILD
===================================================================
--- lib32-libcroco/trunk/PKGBUILD (rev 0)
+++ lib32-libcroco/trunk/PKGBUILD 2015-10-14 07:44:00 UTC (rev 143983)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: GordonGR <ntheo1979 at gmail.com>
+# Contributor: speps <speps.aur at archlinux.org>
+
+pkgname=lib32-libcroco
+pkgver=0.6.8
+pkgrel=2
+pkgdesc='GNOME CSS2 parsing and manipulation toolkit'
+arch=('x86_64')
+url="http://www.gnome.org/"
+license=('LGPL')
+depends=('lib32-glib2' 'lib32-libxml2' 'libcroco')
+makedepends=('gcc-multilib')
+source=("http://ftp.gnome.org/pub/gnome/sources/libcroco/0.6/libcroco-${pkgver}.tar.xz")
+md5sums=('767e73c4174f75b99695d4530fd9bb80')
+
+build() {
+ cd libcroco-${pkgver}
+
+ export CC='gcc -m32'
+ export CXX='g++ -m32'
+ export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+ ./configure \
+ --prefix='/usr' \
+ --libdir='/usr/lib32' \
+ --disable-static
+ make
+}
+
+package() {
+ cd libcroco-${pkgver}
+
+ make DESTDIR="${pkgdir}" install
+ rm -rf "${pkgdir}"/usr/{bin,include,share}
+}
+
+# vim: ts=2 sw=2 et:
Property changes on: lib32-libcroco/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: lib32-librsvg/trunk/PKGBUILD
===================================================================
--- lib32-librsvg/trunk/PKGBUILD (rev 0)
+++ lib32-librsvg/trunk/PKGBUILD 2015-10-14 07:44:00 UTC (rev 143983)
@@ -0,0 +1,41 @@
+# $Id$
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: jtts <jussaar at mbnet.fi>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=lib32-librsvg
+pkgver=2.40.11
+pkgrel=1
+pkgdesc='A SVG viewing library (32-bit)'
+arch=('x86_64')
+url='https://live.gnome.org/LibRsvg'
+license=('LGPL')
+depends=('lib32-gdk-pixbuf2' 'lib32-libcroco' 'lib32-pango' 'librsvg')
+makedepends=('gcc-multilib' 'gobject-introspection' 'intltool' 'python2' 'vala')
+install='librsvg.install'
+source=("http://ftp.gnome.org/pub/gnome/sources/librsvg/${pkgver:0:4}/librsvg-${pkgver}.tar.xz")
+sha256sums=('611ac0f544debd0c9bf1ef5509c990d218e83dd1d8c83297075c4b29796a2e02')
+
+build() {
+ cd librsvg-${pkgver}
+
+ export CC='gcc -m32'
+ export CXX='g++ -m32'
+ export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+ ./configure \
+ --prefix='/usr' \
+ --libdir='/usr/lib32' \
+ --enable-vala \
+ --disable-static
+ make
+}
+
+package() {
+ cd librsvg-${pkgver}
+
+ make DESTDIR="${pkgdir}" install
+ rm -rf "${pkgdir}"/{etc,usr/{bin,include,share}}
+}
+
+# vim: ts=2 sw=2 et:
Property changes on: lib32-librsvg/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: lib32-librsvg/trunk/librsvg.install
===================================================================
--- lib32-librsvg/trunk/librsvg.install (rev 0)
+++ lib32-librsvg/trunk/librsvg.install 2015-10-14 07:44:00 UTC (rev 143983)
@@ -0,0 +1,13 @@
+post_install() {
+ gdk-pixbuf-query-loaders-32 --update-cache
+}
+
+post_upgrade() {
+ post_install
+}
+
+post_remove() {
+ post_install
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list