[arch-commits] Commit in (go-ipfs go-ipfs/repos go-ipfs/trunk go-ipfs/trunk/PKGBUILD)

Anatol Pomozov anatolik at archlinux.org
Mon Oct 26 20:14:01 UTC 2015


    Date: Monday, October 26, 2015 @ 21:14:01
  Author: anatolik
Revision: 145036

Move go-ipfs from AUR to [community]

Added:
  go-ipfs/
  go-ipfs/repos/
  go-ipfs/trunk/
  go-ipfs/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: go-ipfs/trunk/PKGBUILD
===================================================================
--- go-ipfs/trunk/PKGBUILD	                        (rev 0)
+++ go-ipfs/trunk/PKGBUILD	2015-10-26 20:14:01 UTC (rev 145036)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Anatol Pomozov
+# Contributor: kpcyrd <git at rxv.cc>
+# Contributor: Frederik “Freso” S. Olesen <freso.dk at gmail.com>
+# Contributor: Ian Naval <ianonavy at gmail.com>
+
+pkgname=go-ipfs
+pkgver=0.3.8
+pkgrel=2
+pkgdesc='The InterPlanetary File System is a peer-to-peer hypermedia distribution protocol'
+url='http://ipfs.io/'
+arch=(i686 x86_64)
+license=(MIT)
+conflicts=(ipfs)
+replaces=(ipfs)
+depends=(glibc)
+makedepends=(go)
+optdepends=('fuse: for mounting/advanced use')
+source=(go-ipfs-$pkgver.tar.gz::https://github.com/ipfs/go-ipfs/archive/v$pkgver.tar.gz
+	ipfs.service)
+sha512sums=('d991714e8a0ed6111ed5585a59a964f4d16679b0c4d2af335592c742490c420f66ad2454e622dab952230675d336020a0f4747676a463ce2a9cff4dea5827e6b'
+            '1a6bc7fffc3c3640cda3f33c107424edd698c62bd8509731856b8827ea18be1a1845ef0d5ca15325d48d7d871a78daacc011ff9eacea926bc35899850990c1c6')
+
+prepare() {
+  cd go-ipfs-$pkgver
+
+  mkdir -p .gopath/src/github.com/ipfs
+  ln -sf "$PWD" .gopath/src/github.com/ipfs/go-ipfs
+}
+
+build() {
+  cd go-ipfs-$pkgver/cmd/ipfs
+  GOPATH="$PWD/../../.gopath" go build -v
+}
+
+package() {
+  cd go-ipfs-$pkgver
+
+  install -Dm 755 cmd/ipfs/ipfs "$pkgdir/usr/bin/ipfs"
+  install -Dm 644  ../ipfs.service "$pkgdir/usr/lib/systemd/user/ipfs.service"
+  install -Dm 644 misc/completion/ipfs-completion.bash "$pkgdir/etc/bash_completion.d/ipfs"
+  install -Dm 644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+  install -Dm 644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}


Property changes on: go-ipfs/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list