[arch-commits] Commit in (4 files)
Felix Yan
fyan at archlinux.org
Thu Oct 29 03:46:48 UTC 2015
Date: Thursday, October 29, 2015 @ 04:46:48
Author: fyan
Revision: 145211
addpkg: python-ukpostcodeparser 1.0.3.20150130-1
Added:
python-ukpostcodeparser/
python-ukpostcodeparser/repos/
python-ukpostcodeparser/trunk/
python-ukpostcodeparser/trunk/PKGBUILD
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Added: python-ukpostcodeparser/trunk/PKGBUILD
===================================================================
--- python-ukpostcodeparser/trunk/PKGBUILD (rev 0)
+++ python-ukpostcodeparser/trunk/PKGBUILD 2015-10-29 03:46:48 UTC (rev 145211)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-ukpostcodeparser
+pkgname=('python-ukpostcodeparser' 'python2-ukpostcodeparser')
+pkgver=1.0.3.20150130
+_commit=5bf544de5db9e5251cc2b8c8e965e7485ebcbd5f
+pkgrel=1
+pkgdesc="UK Postcode parser"
+arch=('any')
+license=('MIT')
+url="https://github.com/hamstah/ukpostcodeparser"
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+source=("git+https://github.com/hamstah/ukpostcodeparser.git#commit=$_commit")
+sha512sums=('SKIP')
+
+prepare() {
+ cp -a ukpostcodeparser{,-py2}
+}
+
+build() {
+ cd "$srcdir/ukpostcodeparser"
+ python setup.py build
+
+ cd "$srcdir/ukpostcodeparser-py2"
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir/ukpostcodeparser"
+ python setup.py test
+
+ cd "$srcdir/ukpostcodeparser-py2"
+ python2 setup.py test
+}
+
+package_python-ukpostcodeparser() {
+ depends=('python')
+
+ cd ukpostcodeparser
+ python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-ukpostcodeparser() {
+ depends=('python2')
+
+ cd ukpostcodeparser-py2
+ python2 setup.py install --root="${pkgdir}" --optimize=1
+}
+
Property changes on: python-ukpostcodeparser/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list