[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Friday, October 30, 2015 @ 02:52:48
  Author: fyan
Revision: 145263

addpkg: python-cycler 0.9.0-1

Added:
  python-cycler/
  python-cycler/repos/
  python-cycler/trunk/
  python-cycler/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: python-cycler/trunk/PKGBUILD
===================================================================
--- python-cycler/trunk/PKGBUILD	                        (rev 0)
+++ python-cycler/trunk/PKGBUILD	2015-10-30 01:52:48 UTC (rev 145263)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-cycler
+pkgname=('python-cycler' 'python2-cycler')
+pkgver=0.9.0
+pkgrel=1
+pkgdesc="Composable style cycles"
+arch=('any')
+license=('BSD')
+url="http://github.com/matplotlib/cycler"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-coverage' 'python2-coverage')
+source=("git+https://github.com/matplotlib/cycler.git#tag=v$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a cycler{,-py2}
+}
+
+build() {
+  cd "$srcdir/cycler"
+  python setup.py build
+
+  cd "$srcdir/cycler-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/cycler"
+  python run_tests.py
+
+  cd "$srcdir/cycler-py2"
+  python2 run_tests.py
+}
+
+package_python-cycler() {
+  depends=('python-six')
+
+  cd cycler
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-cycler() {
+  depends=('python2-six')
+
+  cd cycler-py2
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-cycler/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property