[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, September 9, 2015 @ 05:38:31
  Author: fyan
Revision: 139655

addpkg: python-jmespath 0.7.1-1

Added:
  python-jmespath/
  python-jmespath/repos/
  python-jmespath/trunk/
  python-jmespath/trunk/PKGBUILD

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Added: python-jmespath/trunk/PKGBUILD
===================================================================
--- python-jmespath/trunk/PKGBUILD	                        (rev 0)
+++ python-jmespath/trunk/PKGBUILD	2015-09-09 03:38:31 UTC (rev 139655)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Chris Severance aur.severach AatT spamgourmet.com
+# Contributor: Chris Fordham <chris [at] fordham-nagy [dot] id [dot] au> aka flaccid
+# Package Source: https://github.com/flaccid/archlinux-packages/blob/master/python-jmespath/PKGBUILD
+
+pkgbase=python-jmespath
+pkgname=(python-jmespath python2-jmespath)
+pkgver=0.7.1
+pkgrel=1
+pkgdesc='A query language for JSON'
+arch=('any')
+url="https://github.com/jmespath/jmespath"
+license=('Apache')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-py' 'python2-py')
+source=("git+https://github.com/jmespath/jmespath.py.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a jmespath.py{,-py2}
+}
+
+build() {
+  cd "$srcdir/jmespath.py"
+  python setup.py build
+
+  cd "$srcdir/jmespath.py-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/jmespath.py"
+  LC_CTYPE=en_US.utf8 nosetests3
+
+  cd "$srcdir/jmespath.py-py2"
+  LC_CTYPE=en_US.utf8 nosetests2
+}
+
+package_python-jmespath() {
+  depends=('python')
+
+  cd $srcdir/jmespath.py
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-jmespath() {
+  depends=('python2')
+
+  cd $srcdir/jmespath.py-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+
+  mv "$pkgdir"/usr/bin/jp{,2}.py
+}


Property changes on: python-jmespath/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property