[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, September 12, 2015 @ 08:09:10
  Author: fyan
Revision: 139952

addpkg: python-logbook 0.10.0-1

Added:
  python-logbook/
  python-logbook/repos/
  python-logbook/trunk/
  python-logbook/trunk/PKGBUILD

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Added: python-logbook/trunk/PKGBUILD
===================================================================
--- python-logbook/trunk/PKGBUILD	                        (rev 0)
+++ python-logbook/trunk/PKGBUILD	2015-09-12 06:09:10 UTC (rev 139952)
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Tomas Schertel<tschertel at gmail.com>
+
+pkgbase=python-logbook
+pkgname=(python-logbook python2-logbook)
+_pypiname=Logbook
+pkgver=0.10.0
+pkgrel=1
+pkgdesc="Logging sytem for Python that replaces the standard library’s logging module"
+arch=('i686' 'x86_64')
+url="http://packages.python.org/Logbook/index.html"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'cython' 'cython2' 'git'
+             'python-six' 'python2-six')
+checkdepends=('python-pytest' 'python2-pytest')
+source=("git+https://github.com/mitsuhiko/logbook.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a logbook{,-py2}
+}
+
+build() {
+  cd "$srcdir/logbook"
+  cython logbook/_speedups.pyx
+  python setup.py build
+
+  cd "$srcdir/logbook-py2"
+  cython2 logbook/_speedups.pyx
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/logbook"
+  LC_CTYPE=en_US.UTF-8 py.test tests
+
+  cd "$srcdir/logbook-py2"
+  LC_CTYPE=en_US.UTF-8 py.test2 tests
+}
+
+package_python-logbook() {
+  depends=('python-six')
+
+  cd "${srcdir}/logbook"
+  python setup.py install --root="${pkgdir}/" --optimize=1
+  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-logbook() {
+  depends=('python2-six')
+
+  cd "${srcdir}/logbook-py2"
+  python2 setup.py install --root="${pkgdir}/" --optimize=1
+
+  install -Dm664 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}


Property changes on: python-logbook/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property