[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, September 14, 2015 @ 07:36:31
  Author: fyan
Revision: 140073

addpkg: python-bcrypt 2.0.0-1

Added:
  python-bcrypt/
  python-bcrypt/repos/
  python-bcrypt/trunk/
  python-bcrypt/trunk/PKGBUILD

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Added: python-bcrypt/trunk/PKGBUILD
===================================================================
--- python-bcrypt/trunk/PKGBUILD	                        (rev 0)
+++ python-bcrypt/trunk/PKGBUILD	2015-09-14 05:36:31 UTC (rev 140073)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Lex Black <autumn-wind at web dot de>
+# Contributor: Igor Nemilentsev <trezorg at gmail.com>
+# Contributor: Alexander Diana <alexander at rouk.org>
+
+_pypiname=bcrypt
+pkgbase=python-bcrypt
+pkgname=("python-bcrypt" "python2-bcrypt")
+pkgver=2.0.0
+pkgrel=1
+pkgdesc="Modern password hashing for your software and your servers"
+arch=('i686' 'x86_64')
+url="https://github.com/pyca/bcrypt"
+license=('APACHE')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-cffi' 'python2-cffi'
+             'python-six' 'python2-six' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("git+https://github.com/pyca/bcrypt.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a "$srcdir/$_pypiname" "$srcdir/$_pypiname-py2"
+}
+
+build() {
+  cd "$srcdir/$_pypiname"
+  python setup.py build
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/$_pypiname"
+  python setup.py ptr
+
+  cd "$srcdir/$_pypiname-py2"
+  python2 setup.py ptr
+}
+
+package_python-bcrypt() {
+  depends=('python-cffi' 'python-six')
+
+  cd ${srcdir}/$_pypiname
+  python setup.py install --prefix=/usr --root=${pkgdir}
+  install -d ${pkgdir}/usr/share/licenses/$pkgname
+  install -m 644 "$srcdir/bcrypt/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+package_python2-bcrypt() {
+  depends=('python2-cffi' 'python2-six')
+
+  cd ${srcdir}/$_pypiname-py2
+  python2 setup.py install --prefix=/usr --root=${pkgdir}
+  install -d ${pkgdir}/usr/share/licenses/$pkgname
+  install -m 644 "$srcdir/bcrypt/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}


Property changes on: python-bcrypt/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property