[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, September 19, 2015 @ 05:59:36
  Author: fyan
Revision: 140684

addpkg: python-peewee 2.6.3-1

Added:
  python-peewee/
  python-peewee/repos/
  python-peewee/trunk/
  python-peewee/trunk/PKGBUILD

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Added: python-peewee/trunk/PKGBUILD
===================================================================
--- python-peewee/trunk/PKGBUILD	                        (rev 0)
+++ python-peewee/trunk/PKGBUILD	2015-09-19 03:59:36 UTC (rev 140684)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Blackleg <blacklg at openaliasbox.org>
+# Contributor: Nidhogg
+# Contributor: juantascon
+
+pkgname=python-peewee
+pkgname=('python-peewee' 'python2-peewee')
+pkgver=2.6.3
+pkgrel=1
+pkgdesc="a little orm"
+url="https://pypi.python.org/pypi/peewee/"
+arch=('i686' 'x86_64')
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'cython' 'cython2' 'git')
+checkdepends=('python-apsw' 'python2-apsw' 'python-flask' 'python2-flask')
+source=("git+https://github.com/coleifer/peewee.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a peewee{,-py2}
+}
+
+build() {
+  cd "$srcdir/peewee"
+  python setup.py build
+
+  cd "$srcdir/peewee-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/peewee"
+  python runtests.py -a
+
+  cd "$srcdir/peewee-py2"
+  python2 runtests.py -a
+}
+
+package_python-peewee() {
+  depends=('python')
+  optdepends=('python-psycopg2: for PostgreSQL database support'
+              'mysql-python: for MySQL database support')
+
+  cd "$srcdir/peewee"
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-peewee() {
+  depends=('python2')
+  optdepends=('python2-psycopg2: for PostgreSQL database support')
+
+  cd "$srcdir/peewee-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  mv "$pkgdir/usr/bin/"pwiz{,2}.py
+}


Property changes on: python-peewee/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property