[arch-commits] Commit in python-braintree/repos (2 files)

[Felix Yan]

    Date: Saturday, September 19, 2015 @ 16:02:30
  Author: fyan
Revision: 140852

archrelease: copy trunk to community-staging-any

Added:
  python-braintree/repos/community-staging-any/
  python-braintree/repos/community-staging-any/PKGBUILD
    (from rev 140851, python-braintree/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: python-braintree/repos/community-staging-any/PKGBUILD (from rev 140851, python-braintree/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-19 14:02:30 UTC (rev 140852)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-braintree
+pkgname=(python-braintree python2-braintree)
+_pkgname=braintree
+pkgver=3.20.0
+pkgrel=2
+pkgdesc="Braintree Python Library"
+arch=('any')
+url="https://www.braintreepayments.com/docs/python"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests')
+checkdepends=('python-nose' 'python2-nose')
+source=("$pkgbase-$pkgver::https://github.com/braintree/braintree_python/archive/${pkgver}.tar.gz")
+sha512sums=('b87e014ebc065a38f7a9cf419452a70a8241b4861a1e8404f6c7a1d9a93e165b73d99fb51c2d8be87e9f205d10d169ac6816dddabc9af396cc625906767d359a')
+
+prepare() {
+  cp -a ${_pkgname}_python-$pkgver{,-py2}
+}
+
+build() {
+  cd ${_pkgname}_python-$pkgver
+  python setup.py build
+
+  cd ../${_pkgname}_python-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd ${_pkgname}_python-$pkgver
+  nosetests3 tests/unit
+
+  cd ../${_pkgname}_python-$pkgver-py2
+  nosetests2 tests/unit
+}
+
+package_python-braintree() {
+  depends=('python-requests')
+
+  cd ${_pkgname}_python-$pkgver
+  python setup.py install -O1 --root "${pkgdir}"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-braintree() {
+  depends=('python2-requests')
+
+  cd ${_pkgname}_python-$pkgver-py2
+  python2 setup.py install -O1 --root "${pkgdir}"
+
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+