[arch-commits] Commit in python-praw/repos (2 files)

[Felix Yan]

    Date: Saturday, September 19, 2015 @ 16:59:33
  Author: fyan
Revision: 140888

archrelease: copy trunk to community-staging-any

Added:
  python-praw/repos/community-staging-any/
  python-praw/repos/community-staging-any/PKGBUILD
    (from rev 140887, python-praw/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-praw/repos/community-staging-any/PKGBUILD (from rev 140887, python-praw/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-19 14:59:33 UTC (rev 140888)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-praw
+pkgname=('python-praw' 'python2-praw')
+pkgver=3.2.1
+pkgrel=2
+pkgdesc="Python Reddit API Wrapper that allows for simple access to reddit's API"
+arch=('any')
+license=('GPL')
+url="http://praw.readthedocs.org"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-decorator' 'python2-decorator'
+             'python-requests' 'python2-requests' 'python-six' 'python2-six'
+             'python-update_checker' 'python2-update_checker' 'git')
+checkdepends=('python-mock' 'python2-mock' 'python-betamax-matchers' 'python2-betamax-matchers')
+source=("git+https://github.com/praw-dev/praw.git#tag=v$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a praw{,-py2}
+}
+
+check() {
+  cd "$srcdir/praw"
+  python setup.py test
+
+  cd "$srcdir/praw-py2"
+  python2 setup.py test
+}
+
+package_python-praw() {
+  depends=('python-decorator' 'python-requests' 'python-six' 'python-update_checker')
+
+  cd "${srcdir}/praw"
+  python setup.py install --root="${pkgdir}" --optimize=1
+}
+
+package_python2-praw() {
+  depends=('python2-decorator' 'python2-requests' 'python2-six' 'python2-update_checker')
+
+  cd "${srcdir}/praw-py2"
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+
+  mv "$pkgdir/usr/bin/praw-multiprocess"{,2}
+}