[arch-commits] Commit in python-routes/repos (2 files)

[Felix Yan]

    Date: Saturday, September 19, 2015 @ 18:48:51
  Author: fyan
Revision: 141004

archrelease: copy trunk to community-staging-any

Added:
  python-routes/repos/community-staging-any/
  python-routes/repos/community-staging-any/PKGBUILD
    (from rev 141003, python-routes/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-routes/repos/community-staging-any/PKGBUILD (from rev 141003, python-routes/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-19 16:48:51 UTC (rev 141004)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: SpepS <dreamspepser at yahoo.it>
+# Contributor: James Bulmer <nekinie at gmail.com>
+
+pkgbase=python-routes
+pkgname=(python-routes python2-routes)
+pkgver=2.2
+pkgrel=2
+pkgdesc="Routing recognition and generation tools"
+arch=("any")
+url="https://pypi.python.org/pypi/Routes"
+license=("custom:BSD")
+makedepends=('python-setuptools' 'python2-setuptools' 'python-repoze.lru' 'python2-repoze.lru' 'python-six' 'python2-six')
+checkdepends=('python-nose' 'python2-nose' 'python-webob' 'python2-webob' 'python-coverage' 'python2-coverage')
+source=("https://pypi.python.org/packages/source/R/Routes/Routes-${pkgver}.tar.gz")
+md5sums=('d62bb225ba7919b5470095528932648b')
+
+prepare() {
+  cp -a Routes-${pkgver}{,-py2}
+}
+
+build() {
+  cd "${srcdir}/Routes-${pkgver}/"
+  python setup.py build
+
+  cd "${srcdir}/Routes-${pkgver}-py2/"
+  python2 setup.py build
+}
+
+check() {
+  cd "${srcdir}/Routes-${pkgver}/"
+  nosetests3
+
+  cd "${srcdir}/Routes-${pkgver}-py2/"
+  nosetests2
+}
+
+package_python-routes() {
+  depends=("python-repoze.lru" 'python-six')
+
+  cd "${srcdir}/Routes-${pkgver}/"
+  python setup.py install --root="${pkgdir}/" --optimize=1
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}
+
+package_python2-routes() {
+  depends=("python2-repoze.lru" 'python2-six')
+
+  cd "${srcdir}/Routes-${pkgver}-py2/"
+  python2 setup.py install --root="${pkgdir}/" --optimize=1
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE.txt"
+}