[arch-commits] Commit in python-secretstorage/repos (2 files)

[Felix Yan]

    Date: Sunday, September 20, 2015 @ 03:51:28
  Author: fyan
Revision: 141108

archrelease: copy trunk to community-staging-any

Added:
  python-secretstorage/repos/community-staging-any/
  python-secretstorage/repos/community-staging-any/PKGBUILD
    (from rev 141107, python-secretstorage/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-secretstorage/repos/community-staging-any/PKGBUILD (from rev 141107, python-secretstorage/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-20 01:51:28 UTC (rev 141108)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Patrice Peterson <runiq at archlinux dot us>
+# Contributor: JonnyJD <arch at JonnyJD.net>
+
+pkgbase=python-secretstorage
+pkgname=(python-secretstorage python2-secretstorage)
+pkgver=2.1.2
+pkgrel=2
+pkgdesc="Securely store passwords and other private data using the SecretService DBus API"
+arch=('any')
+url="https://pypi.python.org/pypi/SecretStorage"
+license=('BSD')
+makedepends=('python-dbus' 'python2-dbus' 'python-crypto' 'python2-crypto')
+checkdepends=('gnome-keyring' 'xorg-server-xvfb' 'dbus-glib')
+source=("https://pypi.python.org/packages/source/S/SecretStorage/SecretStorage-${pkgver}.tar.gz")
+md5sums=('795eadfdfd2f747df146dd1dac9835c0')
+
+prepare() {
+  cp -a SecretStorage-$pkgver{,-py2}
+}
+
+check() {
+  cd SecretStorage-$pkgver
+  xvfb-run -a python -m unittest discover -s tests || warning "Tests failed"
+
+  cd ../SecretStorage-$pkgver-py2
+  xvfb-run -a python2 -m unittest discover -s tests || warning "Tests failed"
+}
+
+package_python-secretstorage() {
+  depends=('python-dbus' 'python-crypto')
+
+  cd SecretStorage-$pkgver
+  python setup.py install -O1 --root="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-secretstorage() {
+  depends=('python2-dbus' 'python2-crypto')
+
+  cd SecretStorage-$pkgver-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}