[arch-commits] Commit in python-boto/repos (2 files)

[Felix Yan]

    Date: Sunday, September 20, 2015 @ 12:54:19
  Author: fyan
Revision: 141238

archrelease: copy trunk to community-staging-any

Added:
  python-boto/repos/community-staging-any/
  python-boto/repos/community-staging-any/PKGBUILD
    (from rev 141237, python-boto/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: python-boto/repos/community-staging-any/PKGBUILD (from rev 141237, python-boto/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-20 10:54:19 UTC (rev 141238)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Kaiting Chen <kaitocracy at gmail.com>
+# Contributor: Aaron Schaefer <aaron at elasticdog.com>
+
+pkgbase=python-boto
+pkgname=(python-boto python2-boto)
+pkgver=2.38.0
+pkgrel=2
+pkgdesc='A Python interface to Amazon Web Services (AWS)'
+arch=('any')
+url='https://github.com/boto/boto'
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-nose' 'python2-nose' 'python-mock' 'python2-mock' 'python-requests'
+              'python2-requests' 'python-httpretty' 'python2-httpretty')
+source=("git+https://github.com/boto/boto.git#tag=$pkgver")
+sha512sums=('SKIP')
+
+prepare() {
+  cp -a boto{,-py2}
+
+  cd boto-py2
+  # python2 fix
+  find . -name '*.py' -type f -print0 | xargs -0 \
+    sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_'
+}
+
+check() {
+  cd boto
+  # Known failure on test_correct_low_level_api_calls: https://bugs.python.org/issue25195
+  python tests/test.py default || warning 'Tests failed'
+
+  cd ../boto-py2
+  python2 tests/test.py default
+}
+
+package_python-boto() {
+  depends=('python')
+
+  cd boto
+
+  python setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  # Remove (somewhat deprecated) tools that conflicts with the python 2 version.
+  rm -r "$pkgdir/usr/bin"
+}
+
+package_python2-boto() {
+  depends=('python2')
+  conflicts=('python-boto<2.32.1-1')
+  replaces=('python-boto<2.32.1-1')
+
+  cd boto-py2
+
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}