[arch-commits] Commit in (4 files)

Felix Yan fyan at archlinux.org
Mon Sep 21 05:54:17 UTC 2015


    Date: Monday, September 21, 2015 @ 07:54:17
  Author: fyan
Revision: 141347

addpkg: python-lazy-object-proxy 1.2.1-1

Added:
  python-lazy-object-proxy/
  python-lazy-object-proxy/repos/
  python-lazy-object-proxy/trunk/
  python-lazy-object-proxy/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: python-lazy-object-proxy/trunk/PKGBUILD
===================================================================
--- python-lazy-object-proxy/trunk/PKGBUILD	                        (rev 0)
+++ python-lazy-object-proxy/trunk/PKGBUILD	2015-09-21 05:54:17 UTC (rev 141347)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-lazy-object-proxy
+pkgname=(python-lazy-object-proxy python2-lazy-object-proxy)
+pkgver=1.2.1
+pkgrel=1
+pkgdesc='A fast and thorough lazy object proxy'
+arch=('i686' 'x86_64')
+url="https://github.com/ionelmc/python-lazy-object-proxy"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-capturelog' 'python2-pytest-capturelog'
+              'python-pytest-benchmark' 'python2-pytest-benchmark')
+source=("git+https://github.com/ionelmc/python-lazy-object-proxy#tag=v$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a python-lazy-object-proxy{,-py2}
+}
+
+build() {
+  cd "${srcdir}/python-lazy-object-proxy"
+  python setup.py build
+
+  cd "${srcdir}/python-lazy-object-proxy-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "${srcdir}/python-lazy-object-proxy"
+  LC_CTYPE=en_US.UTF-8 PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.5:$PYTHONPATH" py.test --ignore=src
+
+  cd "${srcdir}/python-lazy-object-proxy-py2"
+  PYTHONPATH="$PWD/build/lib.linux-$CARCH-2.7:$PYTHONPATH" py.test2 --ignore=src
+}
+
+package_python-lazy-object-proxy() {
+  depends=("python")
+
+  cd "${srcdir}/python-lazy-object-proxy"
+  python setup.py install --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-lazy-object-proxy() {
+  depends=("python2")
+
+  cd "${srcdir}/python-lazy-object-proxy"
+  python2 setup.py install --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-lazy-object-proxy/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property



More information about the arch-commits mailing list