[arch-commits] Commit in python-pyjwt/repos (2 files)

[Felix Yan]

    Date: Tuesday, September 22, 2015 @ 05:17:58
  Author: fyan
Revision: 141430

archrelease: copy trunk to community-staging-any

Added:
  python-pyjwt/repos/community-staging-any/
  python-pyjwt/repos/community-staging-any/PKGBUILD
    (from rev 141429, python-pyjwt/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-pyjwt/repos/community-staging-any/PKGBUILD (from rev 141429, python-pyjwt/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2015-09-22 03:17:58 UTC (rev 141430)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pyjwt
+pkgname=('python-pyjwt' 'python2-pyjwt')
+pkgver=1.4.0
+pkgrel=1
+pkgdesc='JSON Web Token implementation in Python'
+arch=('any')
+url='http://github.com/jpadilla/pyjwt'
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'git')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-pytest-cov' 'python2-pytest-cov')
+source=("git+https://github.com/jpadilla/pyjwt.git#tag=$pkgver")
+md5sums=('SKIP')
+
+prepare() {
+  cp -a pyjwt{,-py2}
+}
+
+build() {
+  cd "$srcdir/pyjwt"
+  python setup.py build
+
+  cd "$srcdir/pyjwt-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/pyjwt"
+  python setup.py ptr
+
+  cd "$srcdir/pyjwt-py2"
+  python2 setup.py ptr || warning "Tests failed"
+}
+
+package_python-pyjwt() {
+  depends=('python-setuptools')
+
+  cd "$srcdir/pyjwt"
+  python3 setup.py install --root="$pkgdir" -O1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-pyjwt() {
+  depends=('python2-setuptools')
+
+  cd "$srcdir/pyjwt-py2"
+  python2 setup.py install --root="$pkgdir" -O1
+  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+  mv "$pkgdir/usr/bin/jwt"{,2}
+}
+